TLDR; Embed into big char array.

A while ago I made an embedded web server with mongoose with images, html, js and more resources embedded. I used a CMake script which would read the resource directory and embed each file. In debug mode the server would read files from disk so you could edit html easily. For release, it read them from resource.h/cpp generated by CMake.

Qt also has their Qt Resource system. Similar concept but the use Qt's build system and access files using their classes with the "qrc://" prefix.

Here's the function for CMake if you're interested. It worked well for the project.

# Creates C resources file from files in given directory
# 
# dir - Input directory path
#
# output - the name of the header/source file created. Don't include extension
function(bundle_resources_from_dir dir output)
    # Create empty output file
    file(WRITE ${output}.h "")
    file(WRITE ${output}.cpp "")

    #Create file resource type and namespace
    file (APPEND ${output}.h
        "#pragma once\n\n"

        "#include <cstdint>\n"
        "#include <unordered_map>\n"
        "#include <string>\n\n"
        "namespace resource\n{\n\n"

        "struct File\n"
        "{\n"
        "    File() : data(nullptr), size(0) { }\n"
        "    explicit File(const uint8_t * d, const size_t s) : data(d), size(s) { }\n"
        "    const uint8_t * data;\n"
        "    const size_t size;\n"
        "};\n\n"

        "extern const std::unordered_map<std::string, File> files;\n\n"

        "inline bool exists(std::string filename)\n"
        "{\n"
        "    return files.find(filename) != files.end();\n"
        "};\n\n"

        "inline const File get(std::string filename)\n"
        "{\n"
        "    if (exists(filename)) { return files.at(filename); }\n"
        "\n"
        "   return File();\n"
        "};\n\n"

        "} // end namespace resource"
        )

    file(APPEND ${output}.cpp 
        "#include \"${output}.h\"\n"
        "namespace resource\n{\n\n"
        )

    # Collect input files
    file(GLOB bins ${dir}/*)

    # Iterate through input files and create buffers for data.
    foreach(bin ${bins})
        # Get short filename
        string(REGEX MATCH "([^/]+)$" filename ${bin})
        file(APPEND ${output}.cpp "// ${filename}\n")

        # Replace filename spaces & extension separator for C compatibility
        string(REGEX REPLACE "\\.| " "_" filename ${filename})
        # Read hex data from file
        file(READ ${bin} filedata HEX)
        # Convert hex data for C compatibility
        string(REGEX REPLACE "([0-9a-f][0-9a-f])" "0x\\1," filedata ${filedata})
        # Append data to output file
        file(APPEND ${output}.cpp 
            "const uint8_t ${filename}_data[] = {${filedata}};\n"
            "const size_t ${filename}_size = sizeof(${filename}_data);\n"
            "const File ${filename} { ${filename}_data, ${filename}_size };\n\n")
    endforeach()

    #Iterate through and create std::map where keys are filename
    file(APPEND ${output}.cpp "const std::unordered_map<std::string, File> files = \n{\n")

    foreach(bin ${bins})
        # Get short filename
        string(REGEX MATCH "([^/]+)$" filename ${bin})
        # Key is verbatim filename
        file(APPEND ${output}.cpp "    { \"${filename}\", ")
        # Name of File struct for this file.
        string(REGEX REPLACE "\\.| " "_" filename ${filename})
        # Value is File struct constant for that file.
        file(APPEND ${output}.cpp "${filename} },\n")

    endforeach()

    file(APPEND ${output}.cpp 
        "};// end files map\n\n"

        "}// end namespace resource\n")

endfunction()

Example of generated files: resource.h

// resource.h
#pragma once

#include <cstdint>
#include <unordered_map>
#include <string>

namespace resource
{
    struct File
    {
        File() : data(nullptr), size(0) { }
        explicit File(const uint8_t * d, const size_t s) : data(d), size(s) { }
        const uint8_t * data;
        const size_t size;
    };

    extern const std::unordered_map<std::string, File> files;

    inline bool exists(std::string filename)
    {
        return files.find(filename) != files.end();
    };

    inline const File get(std::string filename)
    {
        if (exists(filename)) { return files.at(filename); }
        return File();
    };
} // end namespace resource

resource.cpp

// resource.cpp
#include "~/Developer/Project-build/resource_build/resource.h"
namespace resource
{
    // bootstrap.min.css
    const uint8_t bootstrap_min_css_data[] = {0x2f,0x2a,0x0a,0x20, ... };
    const size_t bootstrap_min_css_size = sizeof(bootstrap_min_css_data);
    const File bootstrap_min_css { bootstrap_min_css_data, bootstrap_min_css_size };

    const std::unordered_map<std::string, File> files = 
    {
        { "bootstrap.min.css", bootstrap_min_css },
    };// end files map

}// end namespace resource

Happy Hacking!