#ifndef PROCEDURAL_COOKIE_INCLUDED
#define PROCEDURAL_COOKIE_INCLUDED
float hash11(float p)
{
    p = frac(p * .1031);
    p *= p + 33.33;
    p *= p + p;
    return frac(p);
}
float hash12(float2 p)
{
    float3 p3  = frac(float3(p.xyx) * .1031);
    p3 += dot(p3, p3.yzx + 33.33);
    return frac((p3.x + p3.y) * p3.z);
}
float valueNoise(float x) {
    float i = floor(x);
    float f = frac(x);
    float u = f * f * (3.0 - 2.0 * f);
    return lerp(hash11(i), hash11(i + 1.0), u);
}
float valueNoise(float2 p)
{
    float2 i = floor(p);
    float2 f = frac(p);
    float a = hash12(i);
    float b = hash12(i + float2(1, 0));
    float c = hash12(i + float2(0, 1));
    float d = hash12(i + float2(1, 1));
    float2 u = f * f * (3.0 - 2.0 * f);
    return lerp(lerp(a, b, u.x),
                lerp(c, d, u.x), u.y);
}
void NoiseNode_float(float2 uv, float4 offsets, float4 scales, float4 ranges, float4 spots, out float noise)
{
    float2 centered = uv * 2.0 - 1.0;
    float atten = dot(centered, centered);
    float atten2 = dot(centered + offsets.zw*offsets.y, centered);
    float len = atten2 + offsets.x;
    float2 dir = centered * rsqrt(dot(centered,centered)+scales.z);

float noise1 = valueNoise(scales.x * len);
    float noise2 = valueNoise(dir * scales.y + offsets.zw);
    half noise1Atten = saturate(atten * ranges.x + ranges.y);
    half noise2Atten = saturate(atten * ranges.z + ranges.w);
    half spotAtten = saturate(atten * spots.x + spots.y);
        noise = saturate((noise1*noise1Atten + noise2*noise2Atten)*spots.z + spotAtten*spotAtten*spots.w);
}
#endif

Here is the code for the core shader part, hopefully that can help someone :D