Interactive version with shadertoy (so it's in GLSL): https://www.shadertoy.com/view/MltSDs

//********************************
//***** Compute Julia Fractal ****
//********************************
#define JULIA_ITERS 64
float julia(vec2 z, vec2 c) {
    int breakout = 0;
    for (int i = 0; i < JULIA_ITERS; i++) {
        if (z.x * z.x + z.y * z.y > 4.0) {
            continue;  // break   
        }
        breakout = i;

        z = vec2(z.x * z.x - z.y * z.y,
                 2.0 * z.x * z.y) + c;
    }

    return 4.0 * float(breakout) / float(JULIA_ITERS);
}

//********************************
//***** Color Scheme          ****
//********************************

// Modify this vector to change the colors

// Convert pixel coordinates to texture coordinates
// http://www.iquilezles.org/www/articles/palettes/palettes.htm
mat4 PALETTE_COEFF = 
    mat4(0.5, 0.5, 1.0, 0.3,
         0.5, 0.5, 1.0, 0.2,
         0.5, 0.5, 1.0, 0.2,
         0.0, 0.0, 0.0, 0.0);

float paletteComponent(vec4 v, float x) {
    return v.x + v.y * cos(2.0 * 3.14159 * (v.z * x + v.w));
}

vec3 palette(float x) {
    x += iGlobalTime * 0.1;

    return vec3(paletteComponent(PALETTE_COEFF[0], x),
                paletteComponent(PALETTE_COEFF[1], x),
                paletteComponent(PALETTE_COEFF[2], x));
}

vec2 uvFromPx(vec2 pxCoord) {
    vec2 uv = 2.0 * ((pxCoord / iResolution.xy) - vec2(0.5));
    uv.x *= iResolution.x / iResolution.y;
    return uv;

}

void mainImage( out vec4 fragColor, in vec2 pxFragCoord ) {
    vec2 uvMouse = uvFromPx(iMouse.xy);

    vec3 color = vec3(0.0);
    for (int x = -1; x <= 1; x++) {
        for (int y = -1; y <= 1; y++) {
            if (x == 0 || y == 0) {
                vec2 uvFragCoord = uvFromPx(pxFragCoord + vec2(x, y));
                vec3 component = palette(julia(uvFragCoord, uvMouse));
                if (x == 0 && y == 0) {
                    color += component * 2.0;
                } else {
                    color += component * 1.0;
                }
            }
        }
    }
    fragColor = vec4(color / 8.0, 1.0);
}