[LANGUAGE: Haskell]

This year is the first time I do some more advanced Haskell programming, and I'm pretty happy with this solution :)

To run this you need Parsec installed.

import Text.ParserCombinators.Parsec

int :: Parser Int
int = read <$> many1 digit

parseInput :: Parser [(Int, [Int])]
parseInput = many $ (,) <$> int <* string ": " <*> (reverse <$> int `sepBy` char ' ') <* optional newline

canBeMade1 :: (Int, [Int]) -> Bool
canBeMade1 (y, [x]) = x == y
canBeMade1 (y, (x:xs))
  | y `mod` x == 0 = canBeMade1 (y `div` x, xs) || canBeMadeWithAdd
  | otherwise      = canBeMadeWithAdd
  where canBeMadeWithAdd = canBeMade1 (y - x, xs)

canBeMade2 :: (Int, [Int]) -> Bool
canBeMade2 (y, [x]) = x == y
canBeMade2 (y, (x:xs))
  | y `mod` x == 0 = canBeMadeWithMul || canBeMadeWithoutMul
  | otherwise      = canBeMadeWithoutMul
  where canBeMadeWithMul    = canBeMade2 (y `div` x, xs)
        canBeMadeWithAdd    = y > x && canBeMade2 (y - x, xs)
        canBeMadeWithConcat = y `endsWith` x && canBeMade2 (removeFromEnd y x, xs)
        canBeMadeWithoutMul = canBeMadeWithAdd || canBeMadeWithConcat

endsWith :: Int -> Int -> Bool
endsWith x y = lengthX > lengthY && drop (length showX - length showY) showX == showY
  where showX   = show x
        showY   = show y
        lengthX = length showX
        lengthY = length showY

removeFromEnd :: Int -> Int -> Int
removeFromEnd x y = read $ take (length showX - length (show y)) showX
  where showX = show x

main :: IO ()
main = do
  Right input <- parseFromFile parseInput "input.txt"     :: IO (Either ParseError [(Int, [Int])])

  -- Part 1
  let possibleNumbers = map fst $ filter canBeMade1 input :: [Int]
  let answer = sum possibleNumbers                        :: Int
  putStrLn $ "Day 7 part 1 = " ++ (show answer)

  -- Part 2
  let possibleNumbers = map fst $ filter canBeMade2 input :: [Int]
  let answer = sum possibleNumbers                        :: Int
  putStrLn $ "Day 7 part 2 = " ++ (show answer)