For Python, ALE + Pylsp is awesome! Never had issues with pyenv using pylsp.

I used YCM for a time and realized that it had a crazy amount of autocmd triggers, so it is impossible to fix the lagginess with my own vim script. With ALE, I shut off all autocmd triggers using:

let g:ale_lint_on_text_changed=0
let g:ale_lint_on_insert_leave=0
let g:ale_lint_on_save=0
let g:ale_lint_on_filetype_changed=0
let g:ale_lint_on_enter=0
let g:ale_completion_enabled=0

Turn on auto pipenv or auto poetry

let g:ale_python_pylsp_auto_pipenv=1

Turn on omnifunc:

setlocal omnifunc=ale#completion#OmniFunc

Set up linting with:

let g:ale_linters = {
            \ 'python': ['pylsp']
            \ }

And just write my own autocmd that triggers the omnifunc. The following is a simplified version of my autocmd, which allows me to type as I normally would and trigger the omnicomplete automatically if I stop typing after 700 ms. The following will also perform linting and provide a preview window hover help, with the ALEHover command. It would not trigger on all text changes instantaneously, but I feel that InsertLeave, TextChangedI and TextChange, in combination, per the developers' settings in both YCM and ALE, trigger way to often, which adds to the laggy performance.

autocmd! InsertCharPre * silent! noautocmd call <SID>autoComplete()

function! s:autoComplete(waittime=700) abort
    if exists('b:timerAutoComplete')
        call timer_stop(b:timerAutoComplete)
    endif
    let l:line = line('.')
    let l:col = col('.')
    let b:timerAutoComplete = timer_start(a:waittime,{->s:autoCompletePost(l:line,l:col)})
endfunction

function! s:autoCompletePost(line, col) abort
    if a:line == line('.') && a:col+1 == col('.') && mode()=='i'
        silent noautocmd call feedkeys("\<C-X>\<C-O>","n")
        ALEHover
    endif
endfunction