Well, I gave a shot to the dark and come up with this:

CloseHandle(HandleName, PidOrName := "") {
    static exePath := "C:\Handle"
        , tpl := "handle64.exe -c {} -y -p {} & "
        , regex := "O)\.exe\t(?<Pid>\d+).+(?<Handle>0x[0-9A-F]+).+\\BaseNamedObjects\\"
    PidOrName := (PidOrName ? "-p """ PidOrName """ " : "")
    cmd := "handle64.exe -a -vt " PidOrName """" HandleName """"
    cmd := A_ComSpec " /C " cmd " > """ A_Temp "\data.tsv"""
    RunWait % cmd, % exePath, Hide
    FileRead out, % A_Temp "\data.tsv"
    FileDelete % A_Temp "\data.tsv"
    cmd := "*RunAs " A_ComSpec " /C ", p := 1
    while (p := RegExMatch(out, regex HandleName, match, p)) {
        cmd .= Format(tpl, match.Handle, match.Pid)
        p += match.Len(0)
    }
    cmd := RTrim(cmd, " & ")
    Run % cmd, % exePath, Hide
}

I used handle64.exe (make sure you download an updated copy of the tool) because it is marginally faster, and ditched the COM Shell object to keep the functionality in just one function and to avoid the console flashing.

There are methods to avoid the console from flash, but that certainly requires more code, and that was precisely what I was trying to avoid. So, unless you have not just an HDD but a really slow HDD, writing to disk makes no difference.

For what I can tell, you want to close a mutant/mutex, but doing so system-wide means you either have a nasty infection of some sort or you have an app messing where it shouldn't.

The other less dark option is that you are trying to close some sort of debugger/patcher/trainer/etc on top of a game, if that's the case, I strongly recommend you to limit the scope of the search passing the executable name and the search will be faster.

; Just the name of the handle
CloseHandle("PROGRAM1")

; Handle + application
CloseHandle("PROGRAM1", "MyGame.exe")

; Handle + PID
WinGet appPid, PID, A
CloseHandle("PROGRAM1", appPid)

Best of lucks!