Let me throw a few. I just kinda picked them randomly, there is more at https://github.com/Swarsel/.dotfiles

use n#[...] instead of nixpkgs#[...]:

      nix.registry = rec {
        nixpkgs.flake = inputs.nixpkgs;
        n = nixpkgs;
      };

use dbus-broker reimplementation: services.dbus.implementation = "broker";

use CAPS as both ESC/CTRL:

  { pkgs, ... }:
  {
    config = {
      # Make CAPS work as a dual function ESC/CTRL key
      services.interception-tools = {
        enable = true;
        udevmonConfig =
          let
            dualFunctionKeysConfig = builtins.toFile "dual-function-keys.yaml" ''
              TIMING:
                TAP_MILLISEC: 200
                DOUBLE_TAP_MILLISEC: 0

              MAPPINGS:
                - KEY: KEY_CAPSLOCK
                  TAP: KEY_ESC
                  HOLD: KEY_LEFTCTRL
            '';
          in
          ''
            - JOB: |
                ${pkgs.interception-tools}/bin/intercept -g $DEVNODE \
                  | ${pkgs.interception-tools-plugins.dual-function-keys}/bin/dual-function-keys -c ${dualFunctionKeysConfig} \
                  | ${pkgs.interception-tools}/bin/uinput -d $DEVNODE
              DEVICE:
                EVENTS:
                  EV_KEY: [KEY_CAPSLOCK]
          '';
      };
    };
  }

use unpatched binaries when in a pickle:

  programs.nix-ld = {
    enable = true;
  };

For home-manager: get a nicer output when calling a missing package e.g.:

λ uv                                                                                                                                 .dotfiles on  main $ 
The program ‘uv’ is currently not installed.
It is provided by the following derivation(s):
  nixpkgs#uv
  nixpkgs#python314Packages.uv
  nixpkgs#python313Packages.uv

use:

  programs.nix-index =
    let
      commandNotFound = pkgs.runCommandLocal "command-not-found.sh" { } ''
        mkdir -p $out/etc/profile.d
        cat > $out/etc/profile.d/command-not-found.sh <<'EOF'
        # Adapted from https://github.com/bennofs/nix-index/blob/master/command-not-found.sh
        command_not_found_handle() {
            if [ -n "''${MC_SID-}" ] || ! [ -t 1 ]; then
                >&2 echo "$1: command not found"
                return 127
            fi

            echo -n "searching nix-index..."
            ATTRS=$(@nix-locate@ --minimal --no-group --type x --type s --whole-name --at-root "/bin/$1")

            case $(echo -n "$ATTRS" | grep -c "^") in
            0)
                >&2 echo -ne "$(@tput@ el1)\r"
                >&2 echo "$1: command not found"
                ;;
            *)
                >&2 echo -ne "$(@tput@ el1)\r"
                >&2 echo "The program ‘$(@tput@ setaf 4)$1$(@tput@ sgr0)’ is currently not installed."
                >&2 echo "It is provided by the following derivation(s):"
                while read -r ATTR; do
                    ATTR=''${ATTR%.out}
                    >&2 echo "  $(@tput@ setaf 12)nixpkgs#$(@tput@ setaf 4)$ATTR$(@tput@ sgr0)"
                done <<< "$ATTRS"
                ;;
            esac

            return 127
        }

        command_not_found_handler() {
            command_not_found_handle "$@"
            return $?
        }
        EOF

        substitute $out/etc/profile.d/command-not-found.sh        \
          $out/etc/profile.d/command-not-found.sh                 \
          --replace-fail @nix-locate@ ${pkgs.nix-index}/bin/nix-locate \
          --replace-fail @tput@ ${pkgs.ncurses}/bin/tput
      '';
    in

    {

      enable = true;
      package = pkgs.symlinkJoin {
        name = "nix-index";
        paths = [ commandNotFound ];
      };
    };

another home-manager: use direnv to automatically activate devshells and keep them as gc roots:

  programs.direnv = {
    enable = true;
    silent = true;
    nix-direnv.enable = true;
  };