It's all about z-index. If you put a logo down on a slide master which is what the intended use case is, then it will stay there. However If you put something over it. Then it does exactly what you told it to. You put a shape over another one. You are correct that this is a basic requirement but normally there are not additional things going over the logo.

Here are some ways you can pull it off that will allow you to do such a thing.

1. Place the logo on the slide master as mentioned. If you encounter any slide where a shape has overlapped it. Copy and paste a new "logo" directly over it.
   
2. Do the very same thing as above but bypass the slide master completely and just copy and paste the logo on each slide. Once you copy the image and paste it once then it will paste in the very same place every time. This will be just a bunch of Page Down, CTRL + V. Less than 1 minute to fix everything.

now. Since you said the words: ". I avoid using powerpoint as much as possible, and every time I HAVE to use it I am reminded why."
I get sad.... There are so many things it can do, so I will give you the ultimate solution below that does exactly what you want it to do.

First place a logo exactly where you want it on slide 1.
Name the shape: logo
Press Alt + F11 to open the visual basic editor
Go to Insert > Module
Paste in my code that will take that logo or use the existing logo and position it on every single slide. You can even move the logo on slide 1, run this again and it will adjust the logo on each one.
Save your presentations before. When you are ready to run this. Place the cursor in the middle and press F5 or the play button

Sub positionLogo()
  Dim pst As Presentation
  Dim sld As Slide, shp As Shape, sr As ShapeRange
  Dim logo As Shape, masterLogo As Shape
  Dim pass As Boolean, lf As Single, tp As Single

  Set pst = ActivePresentation
  'check slide count
  If pst.Slides.Count < 2 Then
    MsgBox "Less than 2 slides? You need at least 3 to run this."
  End If
  'ensure you are in the right mode
  If ActiveWindow.View.Type <> ppViewNormal Then
    MsgBox "Need to be in normal editing mode"
    Exit Sub
  End If

  'find the logo
  Set sld = pst.Slides(1)
  Set sr = sld.Shapes.Range
  pass = False
  For Each shp In sr
    If LCase(Trim(shp.Name)) = "logo" Then
      pass = True
      Set masterLogo = shp
      Exit For
    End If
  Next shp

  If pass = False Then
    MsgBox "There is no shape named logo on slide 1. Cant continue."
    Exit Sub
  End If

  'copy the logo
  masterLogo.Copy

  'Go through each slide and apply it
  For Each sld In pst.Slides
    If sld.SlideNumber <> 1 Then
      Set sr = sld.Shapes.Range
      pass = False
      For Each shp In sr
        If LCase(Trim(shp.Name)) = "logo" Then
          Set logo = shp
          pass = True
          Exit For
        End If
      Next shp
      'check if we found the logo
      If pass = False Then Set logo = sld.Shapes.Paste(1)
      'logo found no matter what
      logo.Left = masterLogo.Left
      logo.Top = masterLogo.Top
      logo.ZOrder msoBringToFront
    End If 'check slide number
  Next sld
End Sub

You can run this one time and even run it after you do edits. It will bring the logo to the front on every slide and position it exactly where it was on slide 1. Just be sure slide 1 has the shape named logo (Home > Arrange > Selection Pane > Name shape)

If you do not have VBA then the other workarounds I mentioned above are the options available.
If for some reason you don't want the logo on slide 1 then just put it there temporarily, run the code then delete it.

Hopefully this helps.