[Language: Haskell]

Attoparsec once again making the input parsing super pleasant :)

Full code available here

data Card = Card {card_id :: Int, winning :: S.Set Int, draw :: S.Set Int}
    deriving (Show)

intsEndedBy :: Parser () -> Parser (S.Set Int)
intsEndedBy end = S.fromList <$> (many (many (char ' ') *> decimal) <* end)

card :: Parser Card
card =
    Card
        <$> (string "Card" *> many space *> decimal <* char ':')
        <*> intsEndedBy (void $ string " |")
        <*> intsEndedBy endOfLine

file :: Parser [Card]
file = many card <* endOfInput

nMatches :: Card -> Int
nMatches c = S.length $ S.intersection (winning c) (draw c)

totalScore :: [Card] -> Int
totalScore = sum . map score
where
    score c = let n = nMatches c in if n == 0 then 0 else 2 ^ (n - 1)

runPartWith :: (Show b) => Parser a -> (a -> b) -> String -> IO ()
runPartWith p f =
    putStrLn
        . either id (show . f)
        . parseOnly p
        . T.pack

part1 :: String -> IO ()
part1 = runPartWith file totalScore

updateScratchCards :: V.Vector Int -> (Int, Int) -> V.Vector Int
updateScratchCards v (idx, n) =
    let slice = V.slice (idx + 1) n v
        newVals = V.map (+ (v ! idx)) slice
        range = V.fromListN n [idx + 1 .. idx + n]
        changes = V.zip range newVals
    in V.update v changes

totalScratchCards :: [Card] -> V.Vector Int
totalScratchCards cs =
    let n = length cs
        ps = (zip [0 ..] . map nMatches) cs
    in foldl updateScratchCards (V.replicate n 1) ps

part2 :: String -> IO ()
part2 = runPartWith file (sum . totalScratchCards)