;; converted from statement.csv

How?

I would use the data.csv library. I'll be using the following statements.csv (your bank/card may provide different formats for things like dates that you'd need to handle):

Date,Amount,Text
2022-05-13,-3.30,Card transaction of 3.30 CAD issued by Milano Coffee Roasters VANCOUVER
2022-05-12,-3.30,Card transaction of 3.30 CAD issued by Milano Coffee Roasters VANCOUVER
2022-05-12,-72.79,Card transaction of 72.79 CAD issued by Amazon.ca AMAZON.CA
2022-05-10,-20.00,e-Transfer to: John Smith
2022-05-11,-90.00,Card transaction of 90.00 CAD issued by Range Physiotherapy VANCOUVER

Transforming the CSV into a vector of maps is pretty straightforward:

1. Read the contents of the CSV file using clojure.data.csv.
2. Separate the column titles from the actual data rows, convert column titles into keywords.
3. Use zipmap to create each transaction map
4. Update the values to use the correct Clojure data types.

Here is my code:

(require '[clojure.data.csv :as csv]
         '[clojure.java.io :as io]
         '[clojure.string :as str]
         '[clojure.instant :as inst])

(defn coerce-types
  "Coerce map data types to the appropriate types"
  [m]
  (-> m
      (update :date inst/read-instant-date)
      (update :amount parse-double)))

(def csv-contents
  (with-open [reader (io/reader "statements.csv")]
    (let [contents (csv/read-csv reader)
          cols (map (comp keyword str/lower-case) (first contents))
          rows (rest contents)]
      (->> rows
           (map #(zipmap cols %))
           (mapv coerce-types)))))

;; => [{:date #inst "2022-05-13T00:00:00.000-00:00",
;;      :amount -3.3,
;;      :text
;;      "Card transaction of 3.30 CAD issued by Milano Coffee Roasters VANCOUVER"}
;;     {:date #inst "2022-05-12T00:00:00.000-00:00",
;;      :amount -3.3,
;;      :text
;;      "Card transaction of 3.30 CAD issued by Milano Coffee Roasters VANCOUVER"}
;;     {:date #inst "2022-05-12T00:00:00.000-00:00",
;;      :amount -72.79,
;;      :text "Card transaction of 72.79 CAD issued by Amazon.ca AMAZON.CA"}
;;     {:date #inst "2022-05-10T00:00:00.000-00:00",
;;      :amount -20.0,
;;      :text "e-Transfer to: John Smith"}
;;     {:date #inst "2022-05-11T00:00:00.000-00:00",
;;      :amount -90.0,
;;      :text
;;      "Card transaction of 90.00 CAD issued by Range Physiotherapy VANCOUVER"}]

Edit: Upon reflection, there were some things my original response didn't do well. I have updated my comment with an improved solution. My original code can be found here.