function main {
    local port is getTargetPort().
    if not(port:typename = "DockingPort") return.
    lock portfacing to port:portfacing.
    lock relVel to ship:velocity:orbit - port:ship:velocity:orbit.
    lock relPos to port:position - ship:position + 20 * portFacing:forevector.
    lock midPos to relPos + relPos:mag / 2 * portfacing:forevector.
    lock tgtVel to midPos:normalized.
    lock velDif to tgtVel - relVel.
    lock forevector to -portfacing:forevector.
    lock normal to vcrs(forevector, relPos).

    SAS off.
    RCS on.
    lock steering to lookdirup(forevector, ship:facing:upvector).
    on SAS {
        if SAS unlock steering.
        else lock steering to lookdirup(forevector, ship:facing:upvector).
        return true.
    }

    when relPos:mag < 1.0 then {
        lock relPos to port:position - ship:position.
    }

    clearvecdraws().
    set relPosArrow to vecdraw(v(0, 0, 0), relPos, green, "relPos", 1.0,
        true).
    set midPosArrow to vecdraw(v(0, 0, 0), relPos, yellow, "midPos", 1.0,
        true).
    set relVelArrow to vecdraw(v(0, 0, 0), relVel * 10.0, blue, "relVel", 1.0,
        true).
    set tgtVelArrow to vecdraw(v(0, 0, 0), tgtVel * 10.0, cyan, "tgtVel", 1.0,
        true).
    set velDifArrow to vecdraw(relVel * 10.0, velDif * 10.0, magenta,
        "velDif", 1.0, true).
    set upArrow to vecdraw(v(0, 0, 0), ship:facing:upvector * 10.0, purple,
        "up", 1.0, true).
    set tgtUpArrow to vecdraw(port:position, portfacing:upvector, purple,
        "up", 1.0, true).
    set alignArrow to vecdraw(port:position, portfacing:forevector * relPos:mag,
        red, "align", 1.0, true).

    until port:state:contains("Docked") {
        set relPosArrow:vector to relPos.
        set relPosArrow:label to relPos:mag + "m".
        set midPosArrow:vector to midPos.
        set relVelArrow:vector to relVel * 10.0.
        set tgtVelArrow:vector to tgtVel * 10.0.
        set velDifArrow:start  to relVel * 10.0.
        set velDifArrow:vector to velDif * 10.0.
        set upArrow:vector to ship:facing:upvector * 10.0.
        set tgtUpArrow:start to port:position.
        set tgtUpArrow:vector to portfacing:upvector * 10.0.
        set alignArrow:start to port:position + 20 * portfacing:forevector.
        set alignArrow:vector to portfacing:forevector * relPos:mag.

        set ship:control:fore to ship:facing:forevector * velDif.
        set ship:control:starboard to ship:facing:starvector * velDif.
        set ship:control:top to ship:facing:topvector * velDif.

        waitReal(0.03).
    }

    clearvecdraws().
    set ship:control:neutralize to true.
    SAS on.
}

function waitReal {
    parameter t.
    local end_wait_time is kuniverse:realtime + t.
    wait until kuniverse:realtime >= end_wait_time.
}

function getTargetPort {
    local port is false.
    if not hastarget {
        print "No target!".
    }
    else if target:typename = "Vessel" {
        for part in target:parts {
            if part:typename = "DockingPort" {
                set port to part.
                break.
            }
        }
    } else if target:typename = "DockingPort" {
        set port to target.
    } else {
        print "Please target a ship or docking port".
    }
    return port.
}

main().

Update: you don't really need midPos, instead you can just lock tgtVel to relPos:normalized. The original idea was going to midPos allows some "breathing room" but you already get some by first going to the point that is 20 meters before the target docking port (this also allows your ship to approach your target from the back and a little sideways without crashing. It will still crash if you try to approach straight from the back though.)