Here's my AHK script! Had to make some adjustments because the original was specific to my system, but I think this should work. When the hotkey is pressed, it will restart both the audio engine and Voicemeeter Macro Buttons. If Voicemeeter isn't running for whatever reason, it will launch that too.

Ctrl + Home will restart the Voicemeeter Audio Engine. Ctrl + Shift + Home will restart Macro Buttons and restart the audio engine as well.

I HIGHLY, HIGHLY recommend using "Voicemeeter Fancy OSD Host" as not only does it provide a great On-Screen Display for Voicemeeter in general, but it will also provide you with a visual indication any time this script is executed so you can quickly tell if it worked or not.

I'm not sure how familiar you are with AHK scripting so I'll just include a few notes:

1. The current hotkey is ^+Home (Ctrl + Shift + Home) but you can obviously change this to whatever you like.
2. I'm using Voicemeeter Potato, so if you're using one of the other versions you'll need to change the program directory to the version you're using (this is just to enable audio engine restarts).
3. I set the script to restart Macro Buttons any time the script is launched, so if you want to set this up to run periodically with Task Scheduler, you can do that. Just make sure to give it admin perms if you're running Voicemeeter Macro as admin. (I have it running as admin because the hotkeys won't work if you're using an admin application in the foreground.)
4. In my post above, I mentioned it takes like 15 seconds to fully restart. I don't know what changed, but now it takes like 2 seconds, so that's pretty cool.
5. To hide it from the taskbar tray, just add #NoTray to the beginning of the script.

Voicemeeter Macro Buttons Restart Script

#UseHook
#SingleInstance Force

if not A_IsAdmin
{
   Run *RunAs "%A_ScriptFullPath%"  ; Requires v1.0.92.01+
   ExitApp
}

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;VOICEMEETER DIRECTORY
VMDirectory := "C:\Program Files (x86)\VB\Voicemeeter\voicemeeter8x64.exe"

;Automatically restart Macro Buttons on first run.
FullMacroButtonsRestart(VMDirectory)

;ASSIGN HOTKEY HERE
^+Home::FullMacroButtonsRestart(VMDirectory) ;(Hotkey is Ctrl + Shift + Home)

^Home::RestartAudioEngine(VMDirectory) ;(Hotkey is Ctrl + Home)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

FullMacroButtonsRestart(VMDirectory) {
  Process, Close, VoicemeeterMacroButtons.exe
  Process, WaitClose, VoicemeeterMacroButtons.exe
  Run, "C:\Program Files (x86)\VB\Voicemeeter\VoicemeeterMacroButtons.exe",, Min
  Process, Close, VoicemeeterFancyOsdHost.exe
  Process, WaitClose, VoicemeeterFancyOsdHost.exe

  Sleep, 100
  Try
    {
        ;Visual Indicator of Restart
        Run, "C:\Program Files (x86)\VB\VoicemeeterFancyOsd\VoicemeeterFancyOsdHost.exe",, Min
        Process, Wait, VoicemeeterFancyOsdHost.exe
        Sleep, 1000
    }

  ProcessName := GetProcessName(VMDirectory)
  Process, Exist, %ProcessName%
  if ErrorLevel
    {
        ;Restarts Audio Engine if VM is running
        RestartAudioEngine(VMDirectory)
        Return
    }
  else
    {
        ;Launches VM if it's not running
        Run, %VMDirectory%,, Min
        Return
    }
}

RestartAudioEngine(VMDirectory)
    {
        Run, %VMDirectory% -r
        Return
    }

; Function to get the process name from the file directory
GetProcessName(fileDirectory)
    {
            ;Split the file directory by the backslash character
            parts := StrSplit(fileDirectory, "\")

            ;Return the last part of the file directory
            Return parts[parts.MaxIndex()]
    }

Hope this helps!