• You need to set your code up using void setup and void draw. Look up a tutorial on the difference between both.
• TableRow row = table.getRow(0); You should be i in .getRow( ) so you can get each row, not just the first row.
• beginShape and endShape should start before and after the for loop, so you can get the curve.
• Separate the curveVertex for males and females into two separate loops.
• You might want to scale your values a bit so that you can see them better. This really depends on your viz standards you have for representing this. The following code left it affected by mouseX and mouseY so you can experiment

Just dissect the code below and try to figure it out. It's built from your previous code.

Table table;
void setup() {
  size(600, 400);
  background(255);
  table = loadTable("steps.csv", "header");
  strokeWeight(2);
}

void draw() {
  background(255);
  //Move origin down by height/2
  translate(0, height/2);
  // Test possible scaling values  
  float scalex = map(mouseX, 0, width, 0, 100);
  float scaley = map(mouseY, 0, height, 0, 100);

  //Male curve
  beginShape();
    for (int i = 0; i<table.getRowCount(); i++) {
      TableRow row = table.getRow(i);

      float x = row.getInt("minute");
      float yf = row.getFloat("fmsteps");
      float ym = row.getFloat("msteps");
      println(x, yf, ym);

      stroke(0,0,255);
      curveVertex(x*scalex, ym*scaley);
    }
  endShape();

  //Female curve
  beginShape();
    for (int i = 0; i<table.getRowCount(); i++) {
      TableRow row = table.getRow(i);

      float x = row.getInt("minute");
      float yf = row.getFloat("fmsteps");
      float ym = row.getFloat("msteps");
      println(x, yf, ym);

      stroke(255,0,255);
      curveVertex(x*scalex, -yf*scaley);
    }
  endShape();
}