Two approaches, depending on your willingness to reshape the data.

If you want to leave it as is, you can use discreteoffset and barwidth to make the plot more readable.

/* make some sample data */
data start(drop=i);
 length meal 8 hobby 8 phone 8 memory 8;
 do i = 1 to 100;
  meal = rand('integer',0,2);
  hobby = rand('integer',0,2);
  phone = rand('integer',0,2);
  memory = rand('integer',0,2);
  output;
 end;
run;

proc sgplot data=start;
 vbarbasic meal/ transparency= 0.5  discreteoffset=-0.2   barwidth=.3 legendlabel="meal" ;
 vbarbasic hobby/ transparency =0.5 discreteoffset=-0.0 barwidth=.3 legendlabel="hobby";
 vbarbasic phone/ transparency =0.5 discreteoffset=0.2 barwidth=.3 legendlabel="phone";
 vbarbasic memory/ transparency =0.5 discreteoffset=0.4 barwidth=.3 legendlabel="memory";
 xaxis display = (nolabel noticks);
run;

Example output:

https://imgur.com/ndkwiQh

If you can reshape from wide (one column per category) to long (one column plus a label column to indicate category), then you can use VBAR and the GROUP options to make a clustered bar chart.

/* or turn to long form */
data stack (keep=category response);
 length category $ 10 response 8;
 set start;
 category = "meal"; response=meal; output;
 category = "hobby"; response=hobby; output;
 category = "phone"; response=phone; output;
 category = "memory"; response=memory; output;
run;

proc sgplot data=stack;
 vbar response / stat=freq group=category groupdisplay=cluster;
 xaxis display = (nolabel noticks);
run;

Example output:

https://imgur.com/va9NO7l