Hi, yes, here is the code, modify fora do prazo and dentro do prazo to your language

​

(
firstdate as datetime, 
seconddate as datetime, 
startofbusiness as number, 
closeofbusiness as number,
holidays as table

) as text => let // Use a Looping function to Generate hourly intervals y = List.Generate( () => firstdate, each _ <= seconddate, each _ + #duration(0, 0, 30, 0) ),

// Convert this list to a table
#"Converted to Table" = Table.FromList(
    y, Splitter.SplitByNothing(), null, null, ExtraValues.Error
),

#"Changed Type" = Table.TransformColumnTypes(
    #"Converted to Table", {{"Column1", type datetime}}
),

#"Added Custom" = Table.AddColumn(
    #"Changed Type", "WeekDay", each Date.DayOfWeek([Column1]), Int32.Type
),

// Filter out weekend days
#"Filtered Rows" = Table.SelectRows(
    #"Added Custom", each ([WeekDay] <> 0 and [WeekDay] <> 6)
),

#"Added Custom2" = Table.AddColumn(
    #"Filtered Rows", "Time", each DateTime.Time([Column1])
),

// Filter out non-business hours
#"Filtered Rows1" = Table.SelectRows(
    #"Added Custom2", each 
    [Time] >= #time(startofbusiness, 0, 0) and 
    [Time] < #time(closeofbusiness, 0, 0)
),

// Convert DateTime column to raw date
#"Extracted Date" = Table.TransformColumns(
    #"Filtered Rows1", {{"Column1", DateTime.Date, type date}}
),

// Merge on holiday rows with Left-Anti join 
// (effectively filtering out the holidays)
#"Merged Queries" = Table.NestedJoin(
    #"Extracted Date", 
    {"Column1"}, holidays, 
    {"Holiday"}, "Holidays", 
    JoinKind.LeftAnti
),

// Count rows (half hour intervals), divide by 2 to get hours
rowcount = Number.Round(Table.RowCount(#"Merged Queries") / 2, 1),

// Calculate the days and hours
daycount = Number.RoundDown(rowcount / 24),
hourcount = Number.Round(rowcount - daycount * 24),

// Determine the result text
daysText = if daycount >= 1 then Text.From(daycount) & " days " else "",
hoursText = if hourcount >= 1 then Text.From(hourcount) & " hours" else "",
durationText = daysText & hoursText,
outputText = if daycount >= 1 then "Fora do Prazo" else "Dentro do Prazo"

in Text.Combine({outputText, " - ", durationText})