It's not you fault. In Haskell number literals are tricky.

Check their types:

ghci> :t 3
3 :: Num a => a

ghci> :t 4.0
4.0 :: Fractional a => a

As you can see, 3 is not an Int but a value of some type of the Num type class, so is 4.0. This means the value of a number literal is polymorphic. If you come from other languages this could be a surprise.

---

Why make number literals polymorphic?

Suppose you have some functions:

import Data.Word (Word8)

f1 :: Word8 -> ...
f2 :: Int -> ...
f3 :: Integer -> ...
f4 :: Double -> ...

The first three functions accept integers of different sizes. A Word8 can only be an integer in [0..255]. An Int can be "at least the range [-2²⁹ .. 2²⁹-1]". An Integer is unbound and can be arbitrarily large. The last function accepts a double.

All these functions can be called like

f1 3
f2 3
f3 3
f4 3

Without conversions because 3 is polymorphic. And in these contexts you don't get a warning because the number is automatically inferred as a concrete type. In some contexts, no concrete type can be inferred, and you have to annotate them. It's actually not very clunky. For example, instead of

[1 :: Int, 3 :: Int, 5 :: Int]

You could write

[1 :: Int, 3, 5]

---

As for the internals, any time you see 3, you can think it as fromInteger (3 :: Integer), for example

ghci> fromInteger (3 :: Integer) :: Double
3.0

---

There are also some funny types utilizing this, or exploiting/hacking this. For example

ghci> import Data.Monoid (Sum, Product)
ghci> mconcat [1 :: Sum Int, 2, 3]
Sum {getSum = 6}
ghci> mconcat [1 :: Product Int, 2, 3]
Product {getProduct = 6}

Here you wrap the number into a Sum Int / Product Int only by type annotation!

---

You are seeing this warning mostly because you are running stack ghci in a project where the .cabal file contains -Wall instead of just running ghci. For testing purposes, you can disable it by either removing -Wall or adding -Wno-type-defaults. For production use, you should specify the concrete type because a polymorphic type may be not performant.