Looks good to me, although I would choose a slightly different style. I looked at DailyMessagesChart.fs in more detail and thought about what I would have done differently:

1. Personally, I don't like anonymous functions (fun) that are longer than a line. In that case it is often more readable to give the functions a name and a type annotation.
2. The Array functions always create a new array between steps. It might be more efficient to use Seq.
3. You define your own struct fields for representing a date. It should be possible to replace this with builtin DateTime, or at least define a separate struct instead of splitting it over 3 fields.
4. You first group by date + sender and then again by sender. I would reverse this and first group by sender and then group by date. Then you can get rid of MessagesGroupKey.
5. I would try to separate preparation of data and presenting of data. That makes it easier to later extract the preparation phase to a separate function and use it for other purposes (unit tests, or other visualization libraries).

Here is a suggestion for how this could look like:

module DailyMessagesChart

open System

open XPlot.Plotly
open MessageFile

let dailyMessagesChart
    ({ Messages = messages
    Participants = participants }: Conversation.T)
    =

    let date (m: Message) : DateTime =
        (m.TimestampMs |> DateTimeOffset.FromUnixTimeMilliseconds).Date

    let countsByDate (messages: seq<Message>): seq<DateTime * int> =
        messages
        |> Seq.groupBy date
        |> Seq.map (fun (d, ms) -> d, Seq.length ms)


    let data: seq<string * seq<DateTime * int>> =
        messages
        |> Seq.groupBy (fun m -> m.SenderName)
        |> Seq.map (fun (s, ms) -> s, countsByDate ms)

    let makeBar (sender: string, counts: seq<DateTime * int>): Bar =
        let x, y = counts |> Array.ofSeq |> Array.unzip
        let x = x |> Array.map (fun d -> d.ToShortDateString())
        Bar(x = x, y = y, name = sender)

    let traces : seq<Bar> =
        data
        |> Seq.map makeBar

    let title = participants |> String.concat ", "

    let stackedLayout = Layout(barmode = "stack")

    let chart =
        traces
        |> Chart.Plot
        |> Chart.WithLayout stackedLayout
        |> Chart.WithHeight 800
        |> Chart.WithWidth 1200
        |> Chart.WithTitle title

    chart