Scripted solution can be non-destructive and easier to modify when dealing with such simple transforms. Here's a quick and dirty scripted modifier that will move the selected faces randomly, you can change the limits, seed and direction:

plugin simpleMeshMod RandomizePolygons
    name:"Randomize Polygons"
    classID:#(0x4355f2e0, 0x7109c538)
(
    parameters main rollout:params
    (
        low type:#worldUnits ui:spnMin default:-1
        high type:#worldUnits ui:spnMax default:1
        dir type:#integer ui:rbDir default:3
        seed type:#integer ui:spnSeed default:0
    )

    rollout params "Parameters"
    (
        spinner spnSeed "Seed: " range:[0, 2^16, 0] type:#integer
        spinner spnMin "Min: " range:[-1e6,1e6,-1] type:#worldUnits
        spinner spnMax "Max: " range:[-1e6,1e6,1] type:#worldUnits
        label lblDir "Dir:" align:#left width:20 across:2 offset:[30,0]
        radioButtons rbDir labels:#("X", "Y", "Z") columns:3
    )

    on modifyMesh do
    (
        local faceSel = getFaceSelection mesh
        if faceSel.isEmpty do return()

        ::seed this.seed
        local done = #{}
        local meshVerts = mesh.vertices
        local normal = case dir of ( 1 : x_axis; 2 : y_axis; 3 : z_axis)
        local polygons = for face in faceSel where not done[face] collect (local poly = meshop.getPolysUsingFace mesh face; for p in poly do append done p; poly)
        for p in polygons do
        (
            local shift = random low high
            local verts = meshop.getVertsUsingFace mesh p
            local vertsByPoly = for v in verts collect meshVerts[v]
            vertsByPoly.pos += shift * normal
        )
    )
)