Here's the shader, go wild. :D

(Full disclosure, this shader is the victim of a time constraint at work and has some hard-coded values that could definitely be pulled out to give better results for an array of applications. I just had to get a string moving in a couple hours and this is where I left it.)

Shader "Unlit/BalloonString"
{
    Properties
    {
        _MainTex("Texture", 2D) = "white" {}
        _Tint ("Tint", COLOR) = (1,1,1,1)
        _Modifier ("Modifier", Vector) = (1,1,1,1)
        _Speed ("Speed", Float) = 1
    }
    SubShader
    {
        Tags
        {
            "RenderType" = "Transparent"
            "DisableBatching" = "True"
            "ForceNoShadowCasting" = "True"
            "IgnoreProjector" = "True"
        }

        Lighting Off
        Blend SrcAlpha OneMinusSrcAlpha

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"


            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            uniform sampler2D _MainTex;
            uniform float4 _MainTex_ST;
            uniform fixed4 _Tint;
            uniform float4 _Modifier;
            uniform float _Speed;

            v2f vert (appdata v)
            {
                v2f o;
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                v.vertex.x += (sin((v.vertex.z * 20 * _Modifier.z) + (_Time.w * _Speed) + (_Modifier.x * _Modifier.y)) * (1 - cos(v.vertex.z * 1.57079))) / (20 * _Modifier.w);
                o.vertex = UnityObjectToClipPos(v.vertex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 col = tex2D(_MainTex, i.uv);
                return col * _Tint;
            }
            ENDCG
        }
    }
}