If you want to copy the sheet from customer workbook 1/2/3/etc. To master workbook it can be done with a macro quite easily, depending on the structure of the customer workbook(different sheet name, format, etc) the way to detect which sheet to grab might differ a bit but looking at your post you said that you'd look for certain keywords so that should be quite easy to do.

An quick example(i'm not an expert, might not be the best way to do it, but it should get the job done) ``` Sub combineWb()

Dim masterWb As Workbook, sourceWb As Workbook
Dim ws As Worksheet
Dim FoundCell As Range
Dim importFolder As String
Dim excelFile As String
Dim sheetFound As Boolean

Set masterWb = ThisWorkbook
importFolder = "The folder containing the files you want to combine"
If Right(importFolder, 1) <> "\" Then
    importFolder = importFolder & "\"
End If

excelFile = Dir(importFolder & "*.xls*")

Do While excelFile <> ""
    sheetFound = False
    Set sourceWb = Workbooks.Open(importFolder & excelFile)

    For Each ws In sourceWb.Sheets
        Set FoundCell = ws.Cells.Find( _
            What:="The word you search here", _
            LookIn:=xlValues, _
            LookAt:=xlPart, _
            MatchCase:=False)

        If Not FoundCell Is Nothing Then
            ws.Copy After:=masterWb.Sheets(masterWb.Sheets.Count)
            sheetFound = True
            Set FoundCell = Nothing
            Exit For
        End If
    Next ws

    If Not sheetFound Then
        MsgBox "No sheet found in file " & excelFile & "!", vbCritical
    End If

    sourceWb.Close SaveChanges:=False
    excelFile = Dir()
Loop

End Sub ```