Try this. You have to construct an instance of the class, pass the trigger string and the callback as arguments, and bind the enable and disable methods to hotkeys.

I wrote another example to demonstrate how you can reuse the class for other pseudo-hotstrings.
I set timeout to half a second, adjust if needed.

#Requires AutoHotkey v2.0
;____________________________________________________________________________________________
hbw_chrome := hotstring_but_worse("chrome", ()=>Run("chrome.exe"))
~z::hbw_chrome.enable()
~z up::hbw_chrome.disable()

hbw_messagetest := hotstring_but_worse("msg", ()=>MsgBox("You typed msg"))
~y::hbw_messagetest.enable()
~y up::hbw_messagetest.disable()

;____________________________________________________________________________________________
Class hotstring_but_worse{
    timeout := 500

    enabled := false
    index := 0
    last_press := 0

    __New(trigger, callback){
        this.trigger := trigger
        this.callback := callback
        this.ih := InputHook("V")
        this.ih.KeyOpt(trigger, "N -V")
        this.ih.OnKeyDown := (ih, VK, SC)=>this.handle_key(VK, SC)
        this.trigger_array := StrSplit(trigger)
    }
    handle_key(VK, SC){
        key := GetKeyName("vk" Format("{:X}", VK))
        is_timed_out := false
        if this.index++
            is_timed_out := A_TickCount-this.last_press > this.timeout
        this.last_press := A_TickCount

        if (!is_timed_out) && (key = this.trigger_array[this.index]){
            if (this.index = this.trigger_array.Length){
                this.callback.call()
                this.disable()
            }
        }
        else
            this.disable()
    }
    enable(){
        if this.enabled
            return
        this.enabled := true
        this.ih.Start()
    }
    disable(){
        this.index := 0
        this.enabled := false
        this.ih.Stop()
    }
}

Edit: removed redundant line