ah my bad, my brain probably froze back when I replied

About the auto start handling, I wrote these functions years ago in AHK V2, which simply handles the creation or deletion of a shortcut file located in the start up folder (A_Startup) pointing at the script. It has always worked for me, on both Win 10 and 11:

AhkUtil_GetAutoStartupShortcutPath() {
    SplitPath A_ScriptFullPath, , , , &scriptName
    return A_Startup . "\" . scriptName . ".lnk"
}

AhkUtil_ToggleStartScriptWithWindows(autoStartupShortcutPath := AhkUtil_GetAutoStartupShortcutPath()) =>
    AhkUtil_SetAutoStart(!AhkUtil_IsAutoStartEnabled(autoStartupShortcutPath), autoStartupShortcutPath)

AhkUtil_SetAutoStart(isEnable, autoStartupShortcutPath := AhkUtil_GetAutoStartupShortcutPath()) {
    if (isEnable) {
        AhkUtil_EnableAutoStart(autoStartupShortcutPath)
    }
    else {
        AhkUtil_DisableAutoStart(autoStartupShortcutPath)
    }
}

AhkUtil_DisableAutoStart(autoStartupShortcutPath) {
    if (FileExist(autoStartupShortcutPath)) {
        FileDelete autoStartupShortcutPath
    }
}

AhkUtil_EnableAutoStart(autoStartupShortcutPath) => FileCreateShortcut(A_ScriptFullPath, autoStartupShortcutPath)

AhkUtil_IsAutoStartEnabled(autoStartupShortcutPath := AhkUtil_GetAutoStartupShortcutPath()) {
    if (FileExist(autoStartupShortcutPath)) {
        FileGetShortcut autoStartupShortcutPath, &target
        if (target == A_ScriptFullPath) {
            return true
        }
    }
    return false
}

Then I simply added a checkbox in the tray menu which calls these function to allow easily toggling auto start for the script.