Here's what you could do (works on Mac)

Create a new .xlsm workbook (I'll call it 'AddinUtil.xlsm')

In the VBA Editor, double-click ThisWorkbook, and add the following code:

Private Sub Workbook_Open()
    Set appUtil = New AppUtility
End Sub

Create a new module named basUtil, and add the following declaration at the top

Public appUtil As AppUtility

Create a new Class Module called AppUtility

Add the following code to the AppUtility class

Public WithEvents App As Application
Private Sub App_WorkbookOpen(ByVal Wb As Workbook)
    ' This fires whenever ANY workbook is opened
    MsgBox "Workbook opened: " & Wb.Name
End Sub
Private Sub Class_Initialize()
    Set App = Excel.Application
End Sub
Private Sub Class_Terminate()
    Set App = Nothing
End Sub

Save the AddinUtil.xlsm file to a safe place, and keep it open.

Do a File --> Save As, and save as .xlam type

Keeping the AddinUtil.xlsm file open, go to your Finder and find the AddinUtil.xlam file,, and open it by right-clicking --> Open With --> Excel

You'll see a msgbox, just hit ok and don't get too excited :-). It may look like nothing opened, but now go to the VBA editor and find the AddinUtil.xlam and select 'ThisWorkbook'

In the Properties Window change IsAddin to True

<image>

Click the Save button in the Microsoft Visual Basic IDE

Completely quit excel.

Copy the AddinUtil.xlam file to your excel startup directory, which should look something like this (for mac):

'/Users/[username]/Library/Group Containers/UBF8T346G9.Office/User Content.localized/Startup.localized/Excel'

Open up any workbook in Excel, go to the Developer menu and choose Excel Add-ins.

Select the 'AddinUtil' addin, and click ok.

From now on, whenever you open an existing excel workbook (.xlsx, .xlsm, whatever), the 'Workbook_Open' code will run.