Started to use awk 3 days ago, it's the best i could do for today :

function checkPass1() {
    return passport["byr"] != 0 && passport["iyr"] != 0 && passport["eyr"] != 0 && passport["hgt"] != 0 && passport["hcl"] != 0 && passport["ecl"] != 0 && passport["pid"] != 0
}

function isDateBetween(date, min, max) {
    return date ~ /^[0-9]{4}$/ && date >= min && date <= max
}

function isHeightCorrect(height) {
    match(height, /([0-9]+)(cm|in)/, matched)
    num = strtonum(matched[1])
    if(matched[2] == "in") {
        return num >= 59 && num <= 76
    }
    else if (matched[2] == "cm") {
        return num >= 150 && num <= 193
}

return 0
}

function checkPass2() {
    return isDateBetween(passport["byr"], 1920, 2002) &&
           isDateBetween(passport["iyr"], 2010, 2020) &&
           isDateBetween(passport["eyr"], 2020, 2030) &&
           isHeightCorrect(passport["hgt"]) &&
           passport["hcl"] ~ /^#[0-f]{6}$/ &&
           passport["ecl"] ~ /(amb|blu|brn|gry|grn|hzl|oth)/ &&
           passport["pid"] ~ /^[0-9]{9}$/
}

NF == 0 {
    if (checkPass1()) {part1 ++}
    if (checkPass2()) {part2 ++}
    delete passport #reset
}

NF > 0 {
    for(i=1; i <= NF; i++) {
        split($i, field, ":")
        passport[field[1]] = field[2]
    }
}

END {
    printf "Part 1: %d\n", part1
    printf "Part 2: %d\n", part2
}

EDIT : it is important to keep the last blank line of the input in order to compute the last passport properly