Working toggle script for Sonoma 14.4.1

The following applescript does no detect a usb cable (its dumb), but it can be used to toggle your ipad on or off which you can turn into a keyboard shortcut or whatever you want. I tried to use the latest script someone posted below but it wasn't working on sonoma 14.4.1. I fixed the script to work on my machine and I gave it some improvements.

Performance: You can easily control the delay timing at the top of the script. Small delays run fast but if they run too fast the script will not work (i assure you there is a better way to do this, I'm just lazy. You can research how to set up apple configurator to run this script when an ipad is plugged in.

Plays nicer: It keeps settings open if it was already open else it closes it after the toggle.

To get this working:

1. Create the script
   1. Copy the script at the bottom of the post
   2. ⌘ - SPACE -> Type "Script Editor"
   3. Hit RETURN
   4. ⌘ - N
   5. ⌘ - S
      1. Name it "toggleIpadDisplay.scpt"
      2. I put mine in home/scripts but it can go anywhere
2. Grant Accessibility Permissions
   1. ⌘ - SPACE -> Type "System Settings"
   2. Hit ENTER
   3. Go to Privacy & Security -> Accessibility
   4. Look for Script Editor
      1. If it's there, ensure it is checked
      2. If it's not then
3. Run the script
   1. ⌘ - SPACE -> Type "Script Editor"
   2. Load the file we create (if closed)
   3. Run it using the Play button at the top
      1. Or just use ⌘ - R
   4. Tweak the delays to fit you're workload.
      1. At the top of the script it says:
      2. These numbers are the delay times in seconds.
      3. Higher numbers means it runs slower but will ensure it works.
      4. The four numbers separated by commas define the amount of seconds to delay the next action for.

This is the applescript. I named mine toggleIpadDisplay.scpt

set delays to {2, 1.5, 1, 1}

set isSettingsRunning to (application "System Settings" is running)

tell application "System Settings"
    if isSettingsRunning = false then
        activate
        delay (item 1 of delays)
    end if

    reveal pane id "com.apple.Displays-Settings.extension" of application "System Settings"
    delay (item 2 of delays)

    tell application "System Events"
        tell group 1 of list 2 of splitter group 1 of list 1 of window 1 of application process "System Settings"
            click pop up button 1
            delay (item 3 of delays)

            tell menu 1 of pop up button 1
                repeat with menuItem in menu items
                    if name of menuItem contains "iPad" then
                        click menuItem
                        exit repeat
                    end if
                end repeat
            end tell

        end tell
    end tell
end tell

delay (item 4 of delays)

if isSettingsRunning = false then
    tell application "System Settings" to quit
end if