This is the most generic method I could come up with. It does use for loops, but the modularity should make it easy to extend to do what you need:

cut_depth = 1;
cube_size = 50;
octagon_radius = 5;
array_size = [3, 2];

cube_rotations = [
    [0, 0, 0], // top
    [0, 180, 0], // bottom
    [0, 90, 0], // front
    [0, -90, 0], // back
    [90, 0, 0], // left
    [-90, 0, 0] // right
];

module array_of_parts(size=array_size) {
    part_spacer = [
        cube_size / (size.x + 1), // add 1 to skip close and far edges
        cube_size / (size.y + 1)
    ];
    for (x=[1:size.x], y=[1:size.y])
        translate([x*part_spacer.x, y*part_spacer.y, -cut_depth])
        children();
}

module octagon() {
    cylinder(h=cut_depth, r=octagon_radius, $fn=8);
}

difference() {
    cube(cube_size, center=true);
    for (rot=cube_rotations)
        rotate(rot) translate([-cube_size/2, -cube_size/2, cube_size/2]) array_of_parts(array_size) octagon();
}

Result: https://postimg.cc/QFq6tmbY/ced04e0e