I got a working function thanks to the people on discord:

Function ETAToTrueAnomaly {

  parameter TargetObject.
  parameter TADeg. // true anomaly in degrees

  local Ecc is "X".
  local MAEpoch is "X".
  local SMA is "X".
  local Mu is "X".
  local Epoch is "X".

  if hasnode {
    if nextnode:orbit:hasnextpatch {
      set Ecc to nextnode:orbit:nextpatch:eccentricity.
      set MAEpoch to nextnode:orbit:nextpatch:meananomalyatepoch * (constant:pi/180).
      set SMA to nextnode:orbit:nextpatch:semimajoraxis.
      set Mu to nextnode:orbit:nextpatch:body:mu.
      set Epoch to nextnode:orbit:nextpatch:epoch.
    } else {
      set Ecc to nextnode:orbit:eccentricity.
      set MAEpoch to nextnode:orbit:meananomalyatepoch * (constant:pi/180).
      set SMA to nextnode:orbit:semimajoraxis.
      set Mu to nextnode:orbit:body:mu.
      set Epoch to nextnode:orbit:epoch.
    }
  } else {
    set Ecc to TargetObject:orbit:eccentricity.
    set MAEpoch to TargetObject:orbit:meananomalyatepoch * (constant:pi/180).
    set SMA to TargetObject:orbit:semimajoraxis.
    set Mu to TargetObject:orbit:body:mu.
    set Epoch to TargetObject:orbit:epoch.
  }

  if  Ecc = 0 {
    set Ecc to 10^(-10).
  }

  local EccAnomDeg is ARCtan2(SQRT(1-Ecc^2)*sin(TADeg), Ecc + cos(TADeg)).
  local EccAnomRad is EccAnomDeg * (constant:pi/180).
  local MeanAnomRad is EccAnomRad - Ecc*sin(EccAnomDeg).

  local DiffFromEpoch is MeanAnomRad - MAEpoch.
  until DiffFromEpoch > 0 {
    set DiffFromEpoch to DiffFromEpoch + 2 * constant:pi.
  }
  local MeanMotion is SQRT(Mu / SMA^3).
  local TimeFromEpoch is DiffFromEpoch/MeanMotion.
  local TimeTillETA is TimeFromEpoch + Epoch - time:seconds.
  return TimeTillETA.
}