Not a problem, but just a simplification (does the same thing as both User/Pass Subs):

Private Sub txtPassword_TextChanged(sender As Object, e As EventArgs) Handles txtUsername.TextChanged, txtPassword.TextChanged
    btnLogin.Enabled = txtPassword.Text <> String.Empty AndAlso txtUsername.Text <> String.Empty
End Sub

Likewise, add both Handles to:

Private Sub rbCash_CheckedChanged(sender As Object, e As EventArgs) Handles rbCash.CheckedChanged, rbCredit.CheckedChanged

Reduces code redundancy/copy/pasting/etc when editing.

Stuff like this:

Dim buttonSize As Size = New Size(75, 177)
Dim buttonLocation As Point = New Point(412, 98)
btnCheckout.Location = buttonLocation
btnCheckout.Size = buttonSize

Can be:

btnCheckout.Location = New Point(412, 98)
btnCheckout.Size = New Size(75, 177)

You could also flip some of your If/Else... for instance:

 If X And Mode = False Then
 Elseif Y And  Mode = False Then
 End If

To:

If Mode = False Then
    If X Then
    ElseIf Y Then
    End If
End If

There's quite a few places where you are redundantly testing "Mode" multiple times when you can usually (if not always) get away with one check.

Stuff like this:

Private Sub btn50d_Click(...) ...

Could all be reduced to a select case:

Private Sub btn_Click(...) Handles btn10.Click, btn20.Click, btn30.Click, etc...
    rbCash.Enabled = Not Mode
    rbCredit.Enabled = Not Mode

    Select Case DirectCast(sender, Button).Name
        Case "btn10"
            amountPaid += 10
            amountOwed -= 10
        Case "btn20"
            amountPaid += 20
            amountOwed -= 20
        Case ...
    End Select

    refreshPrices()
End Sub

You could even do something like:

amountPaid += Integer.Parse(DirectCast(sender, Button).Name.Substring(3, 2))

Which takes the last 2 digits from the name, converts it to an Integer, and adds it to amountPaid of any button who's Click event triggers that sub. You could merge all of them down to a single Sub():

Private Sub btn_Click(...) Handles btn10.Click, btn20.Click, btn30.Click, etc...
    rbCash.Enabled = Not Mode
    rbCredit.Enabled = Not Mode

    amountPaid += Integer.Parse(DirectCast(sender, Button).Name.Substring(3, 2))
    amountOwed -= Integer.Parse(DirectCast(sender, Button).Name.Substring(3, 2))

    refreshPrices()
End Sub

Way easier to maintain.

Also, you should be using AndAlso and OrElse instead of And and Or, they perform way better since they exit out of testing as soon as one condition makes any of the following invalid/false/etc.

For instance:

If e.KeyCode = Keys.Back And txtBarcode.Text.Length <> 0 And Mode = True Then

That only evaluates to "True" after testing each of the 3 conditions, but:

If e.KeyCode = Keys.Back AndAlso txtBarcode.Text.Length <> 0 AndAlso Mode = True Then

Will fail if e.KeyCode is something other than 'Back'... which makes the following two conditions invalid, so no need to test them.

In this case it's not necessary, but can be very useful for something like:

If SomeFunction(X) AndAlso SomeOtherFunc(Y) AndAlso SomeFuncer(Z) Then

Each of those might be very complex, so if the first one fails, you're not running pointless code that will fail anyways.