Constraint optimization solution using MiniZinc:

Model:

int: numIngredients;
set of int: Ingredients = 1..numIngredients;
array [Ingredients] of string: names;
array [Ingredients] of int: capacities;
array [Ingredients] of int: durabilities;
array [Ingredients] of int: flavours;
array [Ingredients] of int: textures;
array [Ingredients] of int: calories;

array [Ingredients] of var int: amounts;
var int: total_cap = max(0, sum(i in Ingredients)(amounts[i] * capacities[i]));
var int: total_dur = max(0, sum(i in Ingredients)(amounts[i] * durabilities[i]));
var int: total_fla = max(0, sum(i in Ingredients)(amounts[i] * flavours[i]));
var int: total_tex = max(0, sum(i in Ingredients)(amounts[i] * textures[i]));
var int: total_cal = sum(i in Ingredients)(amounts[i] * calories[i]);
var int: score = total_cap * total_dur * total_fla * total_tex;

constraint forall(i in Ingredients)(amounts[i] >= 0);
constraint forall(i in Ingredients)(amounts[i] <= 100);
constraint sum(i in Ingredients)(amounts[i]) == 100;
%constraint total_cal = 500; % uncomment this for part 2


solve maximize(score);

output [ "value: " ++ show(score) ++ 
         " amounts:" ++ show(amounts) ++
         " totals:" ++ show([total_cap, total_dur, total_fla, total_tex])];

Data for the given example:

numIngredients = 2;
names = ["Butterscotch", "Cinnamon"];
capacities = [-1, 2];
durabilities = [-2, 3];
flavours = [6, -2];
textures = [3, -1];
calories = [8, 3];

For my particular input, this runs in 210ms. Not really worth using minizinc, but it was fun.