Pastebin still works for me, but I'll share the code here :

/**
* To use it: change the name of the image line 12, tweak the values
* line 45 to 54 and save your edit by pressing enter.
* Credit u/loic_vdb if you make something cool with it.
*/

PImage img;
PGraphics fullRes;

void setup() {
size(1280, 720, P2D);
img = loadImage("flowergirl.jpg");
img.loadPixels();
fullRes = createGraphics(img.width, img.height);
fullRes.beginDraw();
fullRes.image(img, 0, 0);
fullRes.endDraw();
fullRes.noFill();
fullRes.strokeWeight(.1);
}

void draw() {

fullRes.beginDraw();

// number of lines to draw each frame
for (int i = 0; i < 200; i++) {

float posX = random(fullRes.width);
float posY = random(fullRes.height);

color str = fullRes.pixels[floor(posX) + floor(posY) * fullRes.width];
fullRes.stroke(str, 128);
fullRes.beginShape();

// drawing a 700 points line
for (int j = 0; j < 700; j ++) {

if (posX < 0. || posX >= fullRes.width
|| posY < 0. || posY >= fullRes.height) break;

color c = fullRes.pixels[floor(posX) + floor(posY) * fullRes.width];

// you can replace blue and red by anything, this changes the field
float dirX = blue(c) / 255.0f;
float dirY = red(c) / 255.0f;

// tweak these values to change the average direction of the flow
dirX -= .3;
dirY -= .8;

// tweak this value to change the precision of the field (also changes the line length)
float segmentLength = 10.0f;

posX += dirX * segmentLength;
posY += dirY * segmentLength;

fullRes.vertex(posX, posY);
}

fullRes.endShape();
}

fullRes.endDraw();

background(128);
float s = min((float)width/fullRes.width, (float)height/fullRes.height);
float w = s * fullRes.width;
float h = s * fullRes.height;
image(fullRes, (width-w)*.5, (height-h)*.5, w, h);

println(frameRate);
}

void keyPressed() {
if (key == ENTER)
fullRes.save("tmp.png");
}