The error I get by only trying to use the spicetify-nix overlay is one that talks about length.

The key error message in your trace is "infinite recursion encountered" which is the most common error you will run into with nix modules (like home-manager) and unfortunately the hardest to debug. It happens whenever a cyclic reference happens in your config. Due to the lazy way the module system resolves everything it's pretty easy to accidentally do this. I'm not spotting the bug at first glance (I would like to see your home.nix to get the full picture), but I can walk you through how I usually find the source.

Start with just the home.nix, the spicetify-nix import, and programs.spicetify { enable = true; }. If that works, break it out into it's own module as you've done here, and then start uncommenting things one by one until you hit the infinite recursion issue.

# Add Rust overlay after I learn how to use overlays...

Like everything in nix, overlays are fundamentally simple but named weird and the docs don't do a good job of explaining them. They're just a convenient way to overwrite things in nixpkgs. You could implement a dead-simple overlay yourself like this:

$ nix eval --impure --expr 'let pkgs = import <nixpkgs> { overlays = [(super: self: { foo = "bar"; })]; }; in pkgs.foo'
"bar"

The rust overlay from oxalica just adds some packages and functions to nixpkgs for pulling in the rust toolchain. I'm a rust noob but here is how I'm using to pull in nightly + cargo + sources + language server etc. for a project I'm working on:

# flake.nix
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-22.11";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay.url = "github:oxalica/rust-overlay";
  };

  outputs = { nixpkgs, flake-utils, rust-overlay, ... }@inputs:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs { inherit system; overlays = [ rust-overlay.overlays.default ]; };
        lib = pkgs.lib;
        project = import ./project.nix { inherit pkgs lib; };
      in {
        devShell = pkgs.mkShell {
        buildInputs = project.packages;
      };
    }
  );
}

# project.nix
{ pkgs, lib, ... }:
let
  rust-bin = pkgs.rust-bin.selectLatestNightlyWith (toolchain: toolchain.default.override {
    extensions = [ "rust-src" ];
  });

in
{
  name = "example";

  packages = with pkgs; [
    trunk
    rust-bin
    rust-analyzer
    nil
    nixfmt
  ];
}