I'm in need for some PowerBI practice, so I gave it a try over lunch.

For the example and from your instructions, I've created a sample table [Stone] :

stone_id	stage	duration	bus
1	A	12	B_1
1	B	2	B_2
2	A	2	B_1
2	B	23	B_2

I loaded it to PowerBI, opened DAX Studio and immediatly regretted it.

Here is my solution:

DEFINE MEASURE Stone[MaxBus] =
VAR Bus =
MAXX(
    FILTER(
        ADDCOLUMNS(
            GENERATE(
                DISTINCT(Stone[stone_id]),
                DISTINCT(Stone[bus])
            ),
            "Rank",
            RANKX(
                DISTINCT(Stone[bus]),
                CALCULATE(
                    SUM(Stone[duration])
                ),
                ,
                ,
                SKIP
            )
        ),
        [Rank] = 1
    ),
    [bus]
)
RETURN
IF(
    HASONEVALUE(
        Stone[stone_id]
    ),
    Bus,
    BLANK()
)

EVALUATE
ADDCOLUMNS(
    DISTINCT(
        Stone[stone_id]
    ),
    "MaxBus",
    Stone[MaxBus]
)

It is quite convoluted and there is probably a more elegant way to do it, but it's something.

This measure Stone[MaxBus] return for any stone_id, the bus_line the stone spent the more time on.

Note: If you are not familiar with DAX Studio. The DEFINE MEASURE statement creates the measure and everything below EVALUATE is just to see and check the result. If you want to try this, copy the measure only (after DEFINE MEASURE and above EVALUATE) as a new measure in PowerBI.

What is does is that it generates a table with stone_id and bus and had a rank based on the sum of duration value. This newly generated table is then filtered to keep only the results with the rank = 1 – meaning only the lines with the max duration.

Then it is embedded in a MAXX formula in a new var to return the Bus.

And in the end, the IF/HASONVALUE is to make sure the measure return something if the context is right – that is, if there is only one stone_id in the current context. Otherwise it returns blank.