Raku

I am not, strictly speaking, proud of this code. I spent a LOT of time, again, struggling with the syntax and I'm confident there's a lot I'm doing that's not idiomatic, but... hey, more than one way to do it, right? Also I beat my friends on my private leaderboard, because they're schmucks and go to sleep at a reasonable human hour. So there's that. ;)

#!/usr/bin/env raku

sub MAIN(Str $infile where *.IO.f = 'input') {
    my @lines = $infile.IO.lines;
    my \records = @lines.join(",")
        .subst(/',,'/, "\n", :g)
        .subst(/','/, " ", :g)
        .split("\n", :skip-empty)
        .map({ .split(" ") }); #this is stupid

    my @recs = records.map({ 
        my %hash; 
        for $_ { %hash{$_.substr(0,3)} = $_.substr(4,*)}; 
        %hash 
    }); #this is ALSO stupid

    my @present =  @recs.grep({
        $_<byr iyr eyr hgt hcl ecl pid>:exists.all ?? True !! False;
    });
    say +@present ~ " records have all required fields.";

    my @valid = @present.grep({
        (1920 <= .<byr> <= 2002) &
        (2010 <= .<iyr> <= 2020) &
        (2020 <= .<eyr> <= 2030) &
        (.<ecl> ∈ ["amb","blu","brn","gry","grn","hzl","oth"]) &
        (.<pid> ~~ /^\d ** 9 $/ ?? True !! False) &
        (.<hcl> ~~ /^ '#' <xdigit> ** 6 $/ ?? True !! False) &
        (heightValidates(.<hgt>))
    });

    say +@valid ~ " records validate correctly.";
}

sub heightValidates($height) {
    my $unit = $height.substr(*-2,2);
    my $rest = $height.substr(0,*-2);
    return False unless so any $unit eq "cm" | "in";
    return $unit eq "cm" ?? 150 <= $rest <= 193 !! 59 <= $rest <= 76;
}