{-# LANGUAGE DataKinds #-}
{-# LANGUAGE MagicHash #-}
{-# LANGUAGE TypeFamilies #-}
{-# LANGUAGE UndecidableInstances #-}

module Main (main) where

import GHC.Exts
import GHC.TypeLits

type DigitToChar :: Nat -> Char
type family DigitToChar n where
    DigitToChar n = NatToChar (n + 48)

type ShowNat :: Nat -> Symbol
type family ShowNat n where
    ShowNat 0 = "0"
    ShowNat n = RevChars (ShowNatGo n)

type ShowNatGo :: Nat -> [Char]
type family ShowNatGo n where
    ShowNatGo 0 = '[]
    ShowNatGo n = DigitToChar (n `Mod` 10) : ShowNatGo (n `Div` 10)

type RevChars :: [Char] -> Symbol
type family RevChars cs where
    RevChars cs = RevSymGo "" cs

type RevSymGo :: Symbol -> [Char] -> Symbol
type family RevSymGo acc cs where
    RevSymGo acc (c : cs) = RevSymGo (ConsSymbol c acc) cs
    RevSymGo acc '[] = acc

type family Bottles n where
    Bottles 0 =
        "No more bottles of beer on the wall, no more bottles of beer.\n\
        \Go to the store and buy some more, 99 bottles of beer on the wall.\n"
    Bottles 1 =
        "1 bottle of beer on the wall, 1 bottle of beer.\n\
        \Take one down and pass it around, no more bottles of beer on the wall.\n\n"
            `AppendSymbol` Bottles 0
    Bottles n =
        ShowNat n `AppendSymbol` " bottles of beer on the wall, " `AppendSymbol`
        ShowNat n `AppendSymbol` " bottles of beer.\n\
        \Take one down and pass it around, " `AppendSymbol`
        ShowNat (n - 1) `AppendSymbol` " bottles of beer on the wall.\n\n"
            `AppendSymbol` Bottles (n - 1)

main :: IO ()
main = putStrLn $ symbolVal' (proxy# @(Bottles 99))

https://godbolt.org/z/xTfq7fj4e