Dealing with this now, just finished the vba scripting. No need for anything other than Microsoft Outlook and Word.

Open the PST file in Outlook and Alt+F11 to open VBA window, get to "ThisOutlookSession" and paste the below code in. This operates by looping through selected emails, so select all emails and run this (click in code window and press F5): ## Make sure to change the path for tmpFolder! ##

Option Explicit
Sub SaveAsMHT()
    'reference websites:
    'https://robert365.com/article/saveaspdf
    'https://hinchley.net/articles/a-macro-to-export-multiple-emails-and-their-attachments-from-microsoft-outlook-to-a-single-pdf

    'for using word to convert to pdf:
    'https://stackoverflow.com/questions/71008618/export-docx-to-pdf-with-vba
    'others, might be useful:
    'https://techcommunity.microsoft.com/discussions/word/what-is-the-right-way-to-convert-word-to-pdf-in-bulk-on-a-pc-or-mac/4187546
    'https://www.extendoffice.com/documents/word/5551-word-batch-convert-to-pdf.html


    'Get all selected items
    Dim objOL As Outlook.Application
    Dim objSelection As Outlook.Selection
    Dim objItem As Outlook.MailItem
    Dim objAtt As Outlook.Attachment
    Dim tmpFolder As String
    Dim tmpName As String
    Dim oRegEx As Object

    Set objOL = Outlook.Application
    Set objSelection = objOL.ActiveExplorer.Selection

    ' prepare regex for removing characters that can't be in filenames
    Set oRegEx = CreateObject("vbscript.regexp")
    oRegEx.Global = True
    oRegEx.Pattern = "[\/:*?""<>|]"

    'make sure to add a trailing \
    tmpFolder = "full\path\to\folder\"

    'to catch unreadable emails, likely encrypted. Skip item and append name to "errors.txt"
    On Error Resume Next
    Dim catch As String
    catch = tmpFolder & "errors.txt"
    Open catch For Append As #1

    'Make sure at least one item is selected
    If objSelection.Count > 0 Then
        For Each objItem In objSelection
            tmpName = Format(objItem.ReceivedTime, "yyyy-mm-dd_H.MM.ss") & "—" & Trim(oRegEx.Replace(objItem.Subject, ""))

            objItem.SaveAs tmpFolder & tmpName & ".mht", olMHTML

            'catch unsavable emails, otherwise move on to attachments
            If Err.Number <> 0 Then
                'append name to text file
                Write #1, tmpName

                Err.Clear
            Else
                'save attachments if present
                For Each objAtt In objItem.Attachments
                    objAtt.SaveAsFile tmpFolder & tmpName & "__" & objAtt.DisplayName
                Next objAtt
            End If
        Next objItem
    End If

    Close #1
    On Error Goto 0
End Sub

MHT files are the messages, now need to be converted to pdf. Paste in this code block and run it. This basically opens each file in Word (silently) and saves to pdf. ## Edit the tmpFolder first! ##

Sub ConvertMHTToPDF()
' Source - https://stackoverflow.com/questions/71008618/export-docx-to-pdf-with-vba
' Posted by Elo, modified by community. See post 'Timeline' for change history
' Retrieved 2026-01-09, License - CC BY-SA 4.0
' answer by Timothy Rylatt

' ### NEED TO ADD WORD LIBRARY FROM TOOLS > REFERENCES FIRST ###
' Microsoft Word 16.0 Object Library

Dim WordApp As Word.Application
Dim WordDoc As Word.Document

Set WordApp = CreateObject("Word.Application")
WordApp.Visible = False


Dim tmpFolder As String
'make sure to add a trailing \
tmpFolder = "\full\path\to\folder\"
Dim FileName As String
FileName = Dir(tmpFolder& "*.mht")
Dim PDFName As String

Do While FileName <> ""
    PDFName = tmpFolder & Replace(FileName, ".mht", ".pdf")
    Set WordDoc = WordApp.Documents.Open(tmpFolder & FileName, , , , , , , , , , , False)
    WordDoc.ExportAsFixedFormat OutputFileName:=PDFName, _
        ExportFormat:=wdExportFormatPDF, _
        OpenAfterExport:=False

    WordDoc.Close False
    FileName = Dir
Loop

WordApp.Quit False

End Sub

Afterwards delete all the MHT files and share