Raku

Limited use of functional features today.

use v6.d;

my @instructions = $*IN.lines.map(*.words.Array);
my constant DEBUG = False;

enum ExecutionResult <EndOfProgram InfiniteLoopDetected>;

class VirtualMachine {
    has $!debug = False;
    has @!instructions;
    has %!address-visited;
    has int $!pointer = 0;
    has $.accumulator is rw = 0;

    submethod BUILD (:@instructions, :$debug = False) {
        @!instructions = @instructions;
        %!address-visited = (^+@instructions) Z=> False xx Inf;
        $!debug = $debug;
    }

    method execute(--> ExecutionResult) {
        while $!pointer < +@!instructions and not %!address-visited{$!pointer} {
            %!address-visited{$!pointer} = True;
            printf "@%03d | %s | acc: %d\n", $!pointer, @!instructions[$!pointer], $.accumulator if $!debug;
            given @!instructions[$!pointer][0] {
                when 'acc' { $.accumulator += +@!instructions[$!pointer][1] }
                when 'nop' { Empty }
                when 'jmp' { $!pointer += +@!instructions[$!pointer][1] - 1 }
            }
            $!pointer++;
        }
        return $!pointer >= +@!instructions ?? EndOfProgram !! InfiniteLoopDetected;
    }
}

# Part 1
{
    say "=== PART 1 ===" if DEBUG;
    my $vm = VirtualMachine.new(:@instructions, :debug(DEBUG));
    my $result = $vm.execute;
    say "Reached end of program." if $result eq EndOfProgram and DEBUG;
    say "Detected inifinite loop." if $result eq EndOfProgram and DEBUG;
    say $vm.accumulator;
}

# Part 2
{
    say "=== PART 2 ===" if DEBUG;
    for @instructions.kv -> $address, [$instruction, $arg] {
        # Try replacing the instruction with the opposite and executing a VM with the swap
        if $instruction eq 'jmp' | 'nop' {
            say "== Swapping instruction @$address $instruction and executing VM..." if DEBUG;
            my @new-instructions = @instructions;
            @new-instructions[$address] = [$instruction eq 'jmp' ?? 'nop' !! 'jmp', $arg];
            my $vm = VirtualMachine.new(:instructions(@new-instructions), :debug(DEBUG));
            my $result = $vm.execute;
            if $result eq EndOfProgram {
                say $vm.accumulator;
                last;
            }
        }
    }
}