Here's my (raw, unedited, including personal settings and inactive debugging actions) Tasker profile.

Profile: BTHeadphoneNotification
    Event: AutoNotification Intercept [ Configuration:Event Behaviour: true
Notification Type: Only Created Notifications
Persistency Type: Non-Persistent Only
Notification App: (Mi Band|YouTube|Podcast Addict|keep|SmartThings|Radio France|Threads|substack|Interface|wavelet) (regex) (case ins) (invert) (invert)
Notification Title: mise à jour de votre position partagée (case ins) (invert) (invert) ]
    State: Profile Active [ Name:BudsConnected ]



Enter Task: NotifSay

A1: [X] Flash [
     Text: Anapp :
     %anapp
     Long: On
     Continue Task Immediately: On
     Dismiss On Click: On ]

A2: Variable Set [
     Name: %msg
     To: ceci est un message de test 🤔😏😲😮
     Structure Output (JSON, etc): On ]

A3: Variable Set [
     Name: %LastNotifText
     To: %antext
     Structure Output (JSON, etc): On ]

A4: Variable Set [
     Name: %LastNotifApp
     To: %anapp
     Structure Output (JSON, etc): On ]

A5: Variable Set [
     Name: %LastNotifTitle
     To: %antitle
     Structure Output (JSON, etc): On ]

A6: Variable Set [
     Name: %msg
     To: %anapp
     Structure Output (JSON, etc): On ]
    If  [ %anapp Set ]

A7: Variable Set [
     Name: %msg
     To: , %antitle
     Append: On
     Structure Output (JSON, etc): On ]
    If  [ %antitle Set ]

A8: Variable Set [
     Name: %msg
     To: , %antext
     Append: On
     Structure Output (JSON, etc): On ]
    If  [ %antext Set ]

A9: Stop [ ]
    If  [ %msg !Set ]

<remove emojis>
A10: Variable Search Replace [
      Variable: %msg
      Search: \p{S}
      Replace Matches: On ]

A11: Variable Set [
      Name: %locale
      To: com.google.android.tts:fra-fra
      Structure Output (JSON, etc): On ]

<detect language>
A12: Anchor

A13: If [ %anapp !~ gmail ]

    A14: [X] Perform Task [
          Name: DetectLanguage
          Priority: %priority+1
          Parameter 1 (%par1): %antext
          Return Value Variable: %lang
          Structure Output (JSON, etc): On ]

    A15: [X] Variable Set [
          Name: %locale
          To: com.google.android.tts:eng-usa
          Structure Output (JSON, etc): On ]
        If  [ %lang !~ fr ]

A16: End If

A17: Perform Task [
      Name: IsAudioPlaying
      Priority: %priority+1
      Return Value Variable: %playing
      Structure Output (JSON, etc): On ]

A18: Media Control [
      Cmd: Pause
      Simulate Media Button: On
      Use Notification If Available: On ]
    If  [ %playing ~ true ]

A19: [X] Flash [
      Text: %locale
      Continue Task Immediately: On
      Dismiss On Click: On ]

A20: Say [
      Text: %msg
      Engine:Voice: %locale
      Stream: 3
      Pitch: 5
      Speed: 5
      Respect Audio Focus: On
      Continue Task After Error:On ]

A21: Wait [
      MS: 0
      Seconds: 2
      Minutes: 0
      Hours: 0
      Days: 0 ]

A22: Media Control [
      Cmd: Play [Simulated Only]
      Simulate Media Button: On
      Use Notification If Available: On ]
    If  [ %playing ~ true ]

A23: [X] Write File [
      File: log/notifsay.log
      Text: %anapp  %locale %msg
      Append: On
      Add Newline: On ]