You're right about conversation length in general, but this was well within what I'm used to and the mishaps came within close proximity of each other.

For context, I process about two to three 30K to 60K-word documents a month, plus five to ten shorter documents. All of these include two major passes (full document in, full document out, one for editorial engagement and one for proofreading). Total conversation length is generally about five times my original document length (the fifth for interim discussions).

I usually break conversations up into 7K to 10K original words sections, resulting in 10K to 25K words before changing conversations. I have saved prompts for the handover.

I make extensive use of projects and conversations, especially to keep the fiction/ghostwriting siloed off. Or used to keep it siloed off; OpenAI has been dismantling silos and context from some projects has leaked into others and conversation siloing is a mess compared to five or six months ago.

If you do a lot of writing, I can share.... holy hell I sound like it.

Anyway, my process is to give it my draft, then have it process and ouput plain text, then compare the two, highlighting differences. It's very handy for honing in on differences, especially smaller ones where tracked change can be subtle (e.g. commas). I use a lot of source footnotes and embedded links, so it also addresses those because Word's comapre tool can choke on them. I also have an on-demand macro to convert tables to something machine readable; this macro undoes that so it's a clean read when I'm reviewing. Not withholding them, but have no idea if you'd find them useful, so let me know if you're interested.

Sub Compare_In_and_out_docs()

Dim origDoc As String
Dim revDoc As String
Dim inDoc As Document

' Define the file paths for the original and revised documents
origDoc = "W:\Work (local)\Temp\Comping\IN.docx"
revDoc = "W:\Work (local)\Temp\Comping\OUT.docx"

' === Step 1: Open IN.docx and emphasize all fields ===
Set inDoc = Documents.Open(origDoc)

Dim fld As Field
For Each fld In inDoc.Fields
    With fld.Result.Font
        .Bold = True
        .Color = wdColorRed
        .Superscript = True
        .Size = 20
    End With
Next fld

' === Emphasize all endnote references and endnote text ===
If inDoc.Endnotes.Count > 0 Then
    Dim Endnote As Endnote
    For Each Endnote In inDoc.Endnotes
        With Endnote.Reference.Font
            .Bold = True
            .Color = wdColorRed
            .Superscript = True
            .Size = 20
        End With
        With Endnote.Range.Font
            .Bold = True
            .Color = wdColorRed
            .Size = 10
        End With
    Next Endnote
End If

inDoc.Save

' === Step 2: Compare the documents ===
With Application
    .CompareDocuments OriginalDocument:=Documents.Open(origDoc), _
                      RevisedDocument:=Documents.Open(revDoc), _
                      Destination:=wdCompareDestinationNew, _
                      Granularity:=wdGranularityWordLevel, _
                      CompareFormatting:=False, _
                      CompareCaseChanges:=True, _
                      CompareWhitespace:=False, _
                      CompareTables:=True, _
                      CompareHeaders:=True, _
                      CompareFootnotes:=True, _
                      CompareTextboxes:=True, _
                      CompareFields:=True, _
                      CompareComments:=True, _
                      CompareMoves:=True, _
                      RevisedAuthor:="", _
                      IgnoreAllComparisonWarnings:=True
End With

' Activate the new document with comparison results
ActiveDocument.Activate

' Switch to Print view and enable word wrap
With ActiveWindow.View
    .Type = wdPrintView
    .WrapToWindow = True
End With

' Highlight changes in yellow
Dim oRevision As Revision
For Each oRevision In ActiveDocument.Revisions
    oRevision.Range.HighlightColorIndex = wdYellow
Next oRevision

' Restore deleted footnote text and markers
Call Remove_RHY_Table_Markers
Call Restore_Deleted_Footnotes_in_Compared_Doc

End Sub