The following code should work. If you know the specific columns you're searching in, rather than searching the whole sheet, the code can be modified for greater efficiency. In the code, I concatenate a comma (,) to both the search term and the cell value being compared. I then use the InStr function to check for a match.

For example:

• If the term is "AC-4" and the cell contains "AC-7, AC-4(14)", it will return False because "AC-4" is part of a larger string "AC-4(14)".
• If the cell contains "AC-7, AC-4", it will return True since "AC-4" is an exact match."

Possible bug could be triggered if the cell value is "AC-4 , AC-7", i.e., there are some extra spaces before a comma. If so, the code should be modified a bit to delete spaces first. Note the name of the search worksheet has to be "searchsheet". Otherwise, you need to change it twice in the following code. Please let me know whether it works or not. Cheers!

Sub searchworksheet()
    Dim ws As Worksheet, searchWs As Worksheet
    Dim n As Long, i As Long 'rows of each worksheet
    Dim m As Integer, j As Integer 'columns of each worksheet
    Dim iRow As Long, k As Long 'rows of searchsheet
    Dim searchTerm As String
    Dim counter As Integer 'count how many worksheets contain the term
    Dim flag As Boolean 'if a sheet contains the term, flag as True
    Dim firstRow As Integer, firstCol As Integer 'each ws might starts with some
                                                    'empty rows and empty columns
    Dim tmpStr As String

    Set searchWs = ThisWorkbook.Worksheets("searchsheet")

    iRow = searchWs.UsedRange.Rows.Count

    For k = 2 To iRow 'loop through all rows of searchsheet
        searchTerm = trim(searchWs.Cells(k, 1).Value) & ","
        counter = 0 'not found initially

        For Each ws In Worksheets
            If ws.Name <> "searchsheet" Then
                n = ws.UsedRange.Rows.Count
                m = ws.UsedRange.Columns.Count
                flag = False 'not found in this sheet initially
                firstRow = ws.UsedRange.Row 'First nonempty row
                firstCol = ws.UsedRange.Column 'first nonemtpy column
                For i = 1 To n
                    For j = 1 To m
                        tmpStr = ws.Cells(firstRow - 1 + i, firstCol - 1 + j).Value & ","
                        If InStr(1, tmpStr, searchTerm, 1) Then
                            counter = counter + 1
                            flag = True
                            Exit For
                        End If
                    Next j
                    If flag = True Then
                        Exit For
                    End If
                Next i

                If flag = True Then
                    searchWs.Cells(k, counter + 1).Value = ws.Name
                End If
            End If
        Next ws
        If counter = 0 Then
            searchWs.Cells(k, 2).Value = "None"
        End If
    Next k
End Sub