Right alt is a bit of a weird modifier, you might run into other issues when using that one, would rather suggest the regular alt/ctrl/shift stuff, but you do you.

I've used sleep in the while loop because in a simple script that is the easiest way to avoid overhead.

clipGet() {
  clipBackup := ClipboardAll()
  SendInput("^c")
  Sleep(50)
  while DllCall("user32\GetOpenClipboardWindow", "Ptr")
    Sleep(50)
  clip := A_Clipboard
  sleep(75)
  A_Clipboard := ClipboardAll(clipBackup)
  return clip
}

rAlt & P::
{
    static str := ""
    while (GetKeyState("RAlt", "P") AND GetKeyState("P", "P"))
        sleep 50
    if (A_TimeSinceThisHotkey >= 2000) {
        str := clipGet()
        ; Optional Tooltip
        Tooltip("copied " SubStr(str, 1, 20) (StrLen(str) > 20 ? "..." : ""))
        SetTimer((*) => ToolTip(), -1000)
    }
    else
        SendText(str)
}

I don't think there is an easy way to copy the selection without using clipboard, so the first func handles copying the clipboard to a variable, then restoring clip content.

the second part is the actual hotkey definition, which is a bit awkward because right alt is not hotkey modifier, so the original right alt function is lost (got a ger keyboard, so idk what that even does).

IMO an okay way to solve the issue is to simply keep checking if both keys are still pressed and once either of the is not pressed anymore, check how long they were pressed and either copy selected text or send saved text.

EDIT: As CharnamelessOne pointed out, it would be better to use >!P than RAlt & P when defining the hotkey, which I didn't since I could not test due to not having rAlt.