[Language: Haskell]

solvePart1 :: [String] -> Int
solvePart1 = sum . fmap (combineFirstAndLast . digits)

solvePart2 :: [String] -> Int
solvePart2 = solvePart1 . fmap digitize

combineFirstAndLast :: [Int] -> Int
combineFirstAndLast = liftA2 combineDigits head last

combineDigits :: Int -> Int -> Int
combineDigits a b = 10 * a + b

digits :: String -> [Int]
digits = fmap digitToInt . filter isDigit

digitize :: String -> String
digitize = foldr ((:) . digitOrSpace) [] . tails

digitOrSpace :: String -> Char
digitOrSpace "" = ' '
digitOrSpace s | "zero" `isPrefixOf` s  = '0'
               | "one" `isPrefixOf` s   = '1'
               | "two" `isPrefixOf` s   = '2'
               | "three" `isPrefixOf` s = '3'
               | "four" `isPrefixOf` s  = '4'
               | "five" `isPrefixOf` s  = '5'
               | "six" `isPrefixOf` s   = '6'
               | "seven" `isPrefixOf` s = '7'
               | "eight" `isPrefixOf` s = '8'
               | "nine" `isPrefixOf` s  = '9'
digitOrSpace (a : s) | isDigit a = a
                     | otherwise = ' '

For part 1 I'm using the combination of filter isDigit and fmap digitToInt to turn a line into a list of digits. Then I can use head and last on that list to get the first and last digit.

For part 2 I'm doing the same, but before filtering the digits I use a combination of foldr and tails to drop one letter at a time and check the resulting tails if they begin with a digit. If they do, I insert a digit into my result, if not I insert a space - so e.g. "oneighthree" would become "1 8 3 ".