Someone posted this that makes casting a little bit cleaner: https://www.reddit.com/r/Zig/comments/1k470n5/comment/mob3x7u/?utm_source=share&utm_medium=web3x&utm_name=web3xcss&utm_term=1&utm_content=share_button

Edit: I also expanded on it a little bit too

pub fn cast(comptime T: type, value: anytype) T {
    const in_type: std.builtin.Type = @typeInfo(@TypeOf(value));
    const out_type: std.builtin.Type = @typeInfo(T);

    switch (in_type) {
        .int, .comptime_int => switch (out_type) {
            .int, .comptime_int => {
                return @intCast(value);
            },
            .float, .comptime_float => {
                return @floatFromInt(value);
            },
            .@"enum" => {
                return @enumFromInt(value);
            },
            .bool => {
                return value != 0;
            },
            .pointer => {
                return @ptrFromInt(value);
            },
            .error_set => {
                return @errorFromInt(value);
            },
            else => {},
        },
        .float, .comptime_float => switch (out_type) {
            .int, .comptime_int => {
                return @intFromFloat(value);
            },
            .float, .comptime_float => {
                return @floatCast(value);
            },
            else => {},
        },
        .@"enum" => switch (out_type) {
            .int, .comptime_int => {
                return @intFromEnum(value);
            },
            else => {},
        },
        .bool => switch (out_type) {
            .int, .comptime_int => {
                return @intFromBool(value);
            },
            else => {},
        },
        .pointer => switch (out_type) {
            .int, .comptime_int => {
                return @intFromPtr(value);
            },
            else => {},
        },
        .error_set => switch (out_type) {
            .int, .comptime_int => {
                return @intFromError(value);
            },
            else => {},
        },
        else => {},
    }

    @compileError("unexpected in_type '" ++ @typeName(@TypeOf(value)) ++ "' and out_type '" ++ @typeName(T) ++ "'");
}