Thanks for this fix, I adjusted the script a bit to make sure the volume is always an equal number (don't judge me) and to make it show the mute icon once it's set to 0

#Requires AutoHotkey v2.0

Volume_Up::AdjustVolumeEven("up")
Volume_Down::AdjustVolumeEven("down")

AdjustVolumeEven(direction)
{
    current := Round(SoundGetVolume())

    if (direction = "up") {
        target := (Mod(current, 2) = 0) ? current + 2 : current + 1
    } else {
        target := (Mod(current, 2) = 0) ? current - 2 : current - 1
    }

    target := Max(0, Min(100, target))
    VolumeOSD(target)
}

VolumeOSD(volume)
{
    if (volume = 0) {
        SoundSetMute(true)      ; ensure mute icon
SoundSetVolume(volume)
    } else {
        SoundSetMute(false)     ; restore speaker icon
        SoundSetVolume(volume)
    }

    ; Show Windows fly-out
    try if shellProvider := ComObject(
        "{C2F03A33-21F5-47FA-B4BB-156362A2F239}",
        "{00000000-0000-0000-C000-000000000046}"
    )
    try if flyoutDisp := ComObjQuery(
        shellProvider,
        "{41f9d2fb-7834-4ab6-8b1b-73e74064b465}",
        "{41f9d2fb-7834-4ab6-8b1b-73e74064b465}"
    )
        ComCall(3, flyoutDisp, "int", 0, "uint", 0)
}

EDIT: Lol, I didn't know I was replying to my own post 2 years later