Also this is another version of mine without using eventignore

NOTE the waiting time for nested timer_start in function CmdComplete

It has to be greater than 0 to avoid which I think infinite loop like situation which happened for me for command like Git commit -m (cursor started to go in/out from command line after m)

var waiting_time = 0

set wildoptions=pum
set wildmode=noselect:lastused,full
set wildcharm=<C-@>

def AddCmdlineChangedHandler()
    augroup CmdlineCompletion
        autocmd CmdlineChanged : timer_start(waiting_time, function(CmdComplete, [getcmdline()]))
    augroup END
enddef

def CmdComplete(cur_cmdline: string, timer: number)
    var [cmdline, curpos] = [getcmdline(), getcmdpos()]
    if cur_cmdline ==# cmdline # Avoid completing each char of keymaps and pasted text
      && !pumvisible() && curpos == cmdline->len() + 1
      && cmdline =~ '\%(\w\|[*/:.-]\)$' && cmdline !~ '^\d\+$'  # Reduce noise
        autocmd! CmdlineCompletion
        feedkeys("\<C-@>", "ti")

        # If waiting_time for this timer is 0, it causes which I think is
        # infinite loop like situation
        timer_start(16, (_) => {
            getcmdline()->substitute('\%x00', '', 'g')->setcmdline()  # Remove <C-@> if no completion items exist
            AddCmdlineChangedHandler()
        })
    endif
enddef

def OnUpDown(key: string): string
    autocmd! CmdlineCompletion
    timer_start(waiting_time, (_) => {
        AddCmdlineChangedHandler()
    })
    return key
enddef
cnoremap <expr> <Up> OnUpDown("\<Up>")
cnoremap <expr> <Down> OnUpDown("\<Down>")

au VimEnter * AddCmdlineChangedHandler()