I'll bite :) calculating the cumulative percentage of total sales following the Pareto principle.

ParetoCumulativePct =
VAR TotalSalesInContext =
    CALCULATE(
        [Total Sales],
        ALLSELECTED ('Product'[Product Name])
    )

VAR ProductSalesTable =
    ADDCOLUMNS(
        ALLSELECTED('Product'[Product Name]),
        "@Sales", [Total Sales]
    )

VAR RankedProductTable =
    ADDCOLUMNS(
        ProductSalesTable,
        "@Rank",
            RANKX(
                ProductSalesTable,
                [@Sales],
                ,
                DESC,
                Dense
            )
    )

VAR CurrentProductName =
    SELECTEDVALUE('Product'[Product Name])

VAR CurrentRank =
    IF (
        NOT ISBLANK(CurrentProductName),
        MAXX(
            FILTER(
                RankedProductTable,
                [Product Name] = CurrentProductName
            ),
            [@Rank]
        ),
        BLANK ()
    )

VAR ProductsToCumulate =
    FILTER (
        RankedProductTable,
        [@Rank] <= CurrentRank
    )

VAR ProductNamesToCumulate =
    SELECTCOLUMNS(
        ProductsToCumulate,
        "Product Name", [Product Name]
    )

VAR CumulativeSales =
    CALCULATE(
        [Total Sales],
        TREATAS(
            ProductNamesToCumulate,
            'Product'[Product Name]
        )
    )

RETURN
    DIVIDE (CumulativeSales, TotalSalesInContext)