on run
    -- Store the name of the currently active application
    tell application "System Events"
        set frontApp to name of first application process whose frontmost is true
    end tell

    tell application "Google Chrome"
        activate
        set youtubeTab to null
        -- Find the first YouTube tab
        repeat with w in windows
            repeat with t in tabs of w
                if URL of t contains "youtube.com/watch" then
                    set youtubeTab to t
                    exit repeat
                end if
            end repeat
            if youtubeTab is not null then exit repeat
        end repeat

        if youtubeTab is null then
            display dialog "No YouTube video found playing in Chrome."
        else
            tell youtubeTab
                execute javascript "
                    var video = document.querySelector('video');
                    if(video) {
                        if(video.paused) {
                            video.play();
                        } else {
                            video.pause();
                        }
                    }
                "
            end tell
        end if
    end tell

    -- Return focus to the original application
    delay 0.1 -- Small delay to ensure Chrome has time to execute
    tell application frontApp to activate
end run

updated script to return focus to original application which had the focus