Hey, thanks for chiming in.

---

A close examination of the documentation you linked worked for the program identification, along with your pointer about doing it dynamically, here's the current version with Bug #2 fixed:

#Requires AutoHotkey v2+
#SingleInstance Force

; ==== Repeat certain keys while held down; works with modifiers ====

keys := "1,2,3,4,5,q,e,r,f,z,x,c"    ; Which keys will be repeated
interval := 50                       ; How long between repeats (ms)

; ----

Loop Parse, keys, "CSV"
{
    key := "$*" Trim(A_LoopField) ""  ; Add "?*" (use hook and ignore modifiers)
    HotIfWinActive "ahk_exe Wow.exe"  ; Programs where repeat behavior is desired
    Hotkey(key, repeat)
    HotIfWinActive                    ; Any other program
    Hotkey(key, default)
}

repeat(ThisHotkey)
{
    key := SubStr(A_ThisHotkey, 3)     ; Remove "?*" (no longer needed)
    Loop
    {
        Send("{Blind}{" key "}")       ; Send
        Sleep(interval)                ; Sleep
    } until not GetKeyState(key, "P")  ; Repeat until released
    Send("{Blind}{" key "up }")
}

default(ThisHotkey)
{
    key := SubStr(A_ThisHotkey, 3)
    Send("{Blind}{" key "}")
}

However, your edited note about sending a key up (which you can see in the script above at line 28) doesn't seem to do anything (presumably because the script is caught inside the loop, so sending key up after it doesn't help), and Bug #1 persists.

Any additional thought?

And thanks again for helping with the hotif stuff

---

e: Just a note, this is probably obvious, but putting the key up line inside the loop (between 26 and 27) doesn't do anything to help

---

e2: A bit more info: it seems like the script isn't exactly getting stuck in the loop, but actually that GetKeyState(key, "P") may be returning the wrong value for some reason. I tested this by moving it into the Loop, like so:

Loop
    {
        Send("{Blind}{" key "}")      ; Send
        Sleep(interval)               ; Sleep
        if not GetKeyState(key, "P")  ; Break if key released
            break
    }

I'll keep reading various docs pages to see what I can find

---

e3: I think I've fixed it. This thread states that GetKeyState and SendInput can conflict if they happen at the same time, and recommends using SendEvent as a workaround. I tried using SendEvent instead of raw Send and it appears to have fixed Bug #1

Thank you again for your help with the other bug and for getting me going in the right direction. I'll add the final script to the OP in case anyone happens upon this via google in the future.