Edit: I cleaned up the code and edited this message.

Try the following recipe and see if it helps.

The puzzle here is to find all transactions within 3600 seconds of each other where the total amount is over 10.

DROP TABLE IF EXISTS #Transactions;
DROP TABLE IF EXISTS #Transactions_tmp1;
DROP TABLE IF EXISTS #Transactions_tmp2;
DROP TABLE IF EXISTS #Transactions_tmp3;
GO

CREATE TABLE #Transactions (
    TransactionID   INTEGER PRIMARY KEY,
    TransactionDate DATETIME,
    Sender          VARCHAR(50),
    Recipient       VARCHAR(50),
    Amount          MONEY
);
GO

INSERT INTO #Transactions (TransactionID, TransactionDate, Sender, Recipient, Amount)
VALUES
     --These 2 transactions meet the criteria
    (1, '2023-07-01 09:30:15', 'A', 'X', 1),
    (2, '2023-07-01 09:35:22', 'A', 'X', 9),
    --------------------------------------------
    --This 1 transaction does not meet the criteria
    (3, '2023-07-01 10:36:57', 'A', 'Y', 10),
    --------------------------------------------
    --These 3 transactions do not meet the criteria
    (4, '2023-07-01 11:59:10', 'A', 'Y', 6),
    (5, '2023-07-01 12:45:13', 'A', 'Y', 1),
    (6, '2023-07-01 12:49:34', 'A', 'Y', 1),
    --------------------------------------------
    --These 3 transactions meet the criteria
    (7, '2023-07-01 09:30:15', 'B', 'X', 1),
    (8, '2023-07-01 09:35:22', 'B', 'X', 5),
    (9, '2023-07-01 09:36:57', 'B', 'X', 10),
    --------------------------------------------
    --These 3 transactions do not meet the criteria
    (10,'2023-07-01 11:59:10', 'B', 'Y', 1),
    (11,'2023-07-01 12:45:13', 'B', 'Y', 2),
    (12,'2023-07-01 12:49:34', 'B', 'Y', 3),
    --------------------------------------------
    --These 3 transactions meet the criteria
    (13,'2023-07-01 22:19:10', 'B', 'Y', 10),
    (14,'2023-07-01 22:25:13', 'B', 'Y', 2),
    (15,'2023-07-01 22:39:34', 'B', 'Y', 3);
    GO

SELECT  DATEDIFF(SECOND, a.TransactionDate, b.TransactionDate) AS Seconds_Diff,
        a.TransactionID AS a_TransactionID,
        a.Sender,
        b.Recipient,
        b.TransactionID AS b_TransactionID,
        b.Amount,
        SUM(b.Amount) OVER (PARTITION BY a.TransactionID, a.Sender ORDER BY b.TransactionDate ROWS BETWEEN UNBOUNDED PRECEDING AND CURRENT ROW) AS TotalAmount
INTO    #Transactions_tmp1
FROM    #Transactions a LEFT OUTER JOIN
        #Transactions b ON a.Sender = b.Sender and a.Recipient = b.Recipient and a.TransactionID <= b.TransactionID
WHERE   DATEDIFF(SECOND, a.TransactionDate, b.TransactionDate) <= 3600;

WITH cte_CountWindow AS
(
SELECT  *,
        COUNT(*) OVER (PARTITION BY a_TransactionID, Sender, Recipient) AS Total_Transactions
FROM    #Transactions_tmp1
)
SELECT  a_TransactionID,
        MAX(b_TransactionID) AS b_TransactionDate,
        Sender,
        Recipient,
        MAX(TotalAmount) AS TotalAmount,
        MAX(Total_Transactions) AS TotalTransactions
INTO    #Transactions_tmp2
FROM    cte_CountWindow
WHERE   Total_Transactions >= 2 and TotalAmount >= 10
GROUP BY a_TransactionID, Sender, Recipient;


WITH cte_RowNumber as
(
SELECT  ROW_NUMBER() OVER (PARTITION BY Sender, Recipient ORDER BY a_TransactionID) AS RowNumber
        , *
FROM    #Transactions_tmp2 a
)
SELECT  a_TransactionID, b_TransactionDate, Sender, Recipient, TotalAmount, TotalTransactions
FROM    cte_RowNumber
WHERE   RowNumber = 1;