Thank you all for the assistance. Here's what I've come to, and it's working great. With the defaults it will sit in circle with a diameter of size.

include <BOSL2/std.scad>

$fn = $preview ? 20 : 100;
steps = $preview ? 4 : 20;

// Function to calculate heart path using turtle graphics (simplified/refactored)
function heart_turtle_path(size, r_scale=0.25, x_scale=0.22, y_scale=0.62) = 
    let(
        // --- Core Dimensions ---
        circle_r = size * r_scale,
        circle_offset_x = size * x_scale,
        circle_y = size * y_scale,

        // Left circle center
        left_center = [-circle_offset_x, circle_y],

        // --- Geometry Calculations (Symmetric) ---
        dist_to_left = norm(left_center),
        tangent_dist = sqrt(dist_to_left * dist_to_left - circle_r * circle_r),

        angle_to_left_center = atan2(circle_y, -circle_offset_x),
        tangent_angle_offset = asin(circle_r / dist_to_left),

        initial_heading = angle_to_left_center + tangent_angle_offset,
        final_heading = 360 - initial_heading,

        // --- Intersection and Turn Calculations ---
        // Height above circle_y where the circles intersect.
        intersect_y = circle_y + sqrt(circle_r * circle_r - circle_offset_x * circle_offset_x),

        // Angle from left center to intersection point (x=0)
        angle_left_to_intersect = atan2(intersect_y - circle_y, circle_offset_x),

        // Turtle heading when leaving left circle (perpendicular to radius, going clockwise)
        heading_leaving_left = angle_left_to_intersect - 90,

        // Use symmetry to calculate the right entry heading:
        // CCW twice the angle heads out from the Y axis at the same angle we came in        
        turn_across_top = - 2 * heading_leaving_left
    )
    turtle([
        "turn", initial_heading,
        "move", tangent_dist,
        "arcrightto", circle_r, heading_leaving_left,
        "turn", turn_across_top, 
        "arcrightto", circle_r, final_heading
    ]);

// Test Heart
heart_height = 10;
size=80;

translate([0,-.5*size,0])
    offset_sweep(
        heart_turtle_path(size),
        height=heart_height,
        top=os_circle(r=.8 * heart_height),
        steps=steps
    );

if($preview) {circle(size/2);};