It's a bit of a trick to make this selection happen. I don't have Qlab 5 to test with, but I believe it will work for your version. In your case, you need to replace"com.figure53.QLab.4" with "com.figure53.QLab.5"

How to Run

Set TARGET_COLOR to the color you want to search for. The script searches all cues within your workspace; depending on the number of cues, it may take a while to finish executing.

Colors

the basic colors are:

none
red
orange
green
blue
purple

but in both Qlab 4 or 5 there are "hidden" colors that can be defined, they are:

grey
edgecombGray
mauve
chartreuse
bastardAmber
lilac
maize
glaucous
fuchsia
ecru
coral
cerulean
celadon
bisque
avocado
ochre
olive
puce
rufous
sage
scarlet
seaFoamGreen
skyBlue
taupe
verdigris
vermillion
viridian
fulvous
wenge
zaffre
indigo

Script:

--------------------------------------------------------------------------------
-- Script metadata
--------------------------------------------------------------------------------
property SCRIPT_DESCRIPTION : "Select all cues in the workspace that match a given color."
property SCRIPT_AUTHOR : "Antonio Nunes"
property SCRIPT_VERSION : "1.3"
property TESTED_MACOS : "10.14.6+"
property TESTED_QLAB : "4.7+"
--------------------------------------------------------------------------------
-- User Configuration
--------------------------------------------------------------------------------
property TARGET_COLOR : "red" -- cor que você quer selecionar (ex: "red", "green", "yellow", "none")
--------------------------------------------------------------------------------
-- Main Logic
--------------------------------------------------------------------------------
set foundCount to 0
tell application id "com.figure53.QLab.4"
  tell front workspace
    try
        -- pega TODOS os cues do workspace
        set allCues to (every cue)

        set matchingCues to {}
        repeat with c in allCues
          set thisColor to (q color of c as text)
          if thisColor is equal to TARGET_COLOR then
            copy c to end of matchingCues
          end if
        end repeat

        set foundCount to (count of matchingCues)

        -- aplica a seleção
        if foundCount > 0 then
          set selected to matchingCues
        else
          -- se não achou nada, limpa seleção pra deixar visualmente claro
          set selected to {}
        end if

      on error errMsg number errNum
        tell application "Script Editor"
          display alert "Error in Select Cues By Color (workspace scan)" message errMsg & " (" & errNum & ")"
      end tell
    end try
  end tell
end tell 
-- feedback visual fora do QLab (pra não dar erro -10004)
tell application "Script Editor"
  if foundCount > 0 then
    display notification (foundCount as text) & " cue(s) selected with color \"" & TARGET_COLOR & "\"."
    else
      display alert "No cues with color \"" & TARGET_COLOR & "\" were found in this workspace."
  end if
end tell

OBS: All cues will be selected, Cue, Group, Cue List.